net-misc/networkmanager-openvpn: version bump to 1.2.2 to 1.2.4

dbus-glib is not needed anymore.
Fixes bug #588388 as well.

Package-Manager: portage-2.3.0

1 files changed, 60 insertions, 0 deletions

diff --git a/net-misc/networkmanager-openvpn/networkmanager-openvpn-1.2.4.ebuild b/net-misc/networkmanager-openvpn/networkmanager-openvpn-1.2.4.ebuild
new file mode 100644
index 000000000000..176915dca07e
--- /dev/null
+++ b/net-misc/networkmanager-openvpn/networkmanager-openvpn-1.2.4.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit autotools gnome2 user
+
+DESCRIPTION="NetworkManager OpenVPN plugin"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="gtk test"
+
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	>=net-misc/networkmanager-1.2.0:=
+	>=net-misc/openvpn-2.1_rc9
+	gtk? (
+		>=app-crypt/libsecret-0.18
+		>=gnome-extra/nm-applet-1.2.0
+		>=x11-libs/gtk+-3.4:3
+	)
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	>=dev-util/intltool-0.35
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	enewgroup nm-openvpn
+	enewuser nm-openvpn -1 -1 -1 nm-openvpn
+}
+
+src_prepare() {
+	# Test will fail if the machine doesn't have a particular locale installed
+	# FAIL: (tls-import-data) unexpected 'ca' secret value, upstream bug #742708
+	sed '/test_non_utf8_import (plugin, test_dir)/ d' \
+		-i properties/tests/test-import-export.c || die "sed failed"
+
+	# Fix underlinking issue, bug #588388, upstream #769783
+	eapply "${FILESDIR}"/${PN}-1.2.4-underlinking-*.patch
+
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# --localstatedir=/var needed per bug #536248
+	gnome2_src_configure \
+		--localstatedir=/var \
+		--disable-more-warnings \
+		--disable-static \
+		--with-dist-version=Gentoo \
+		$(use_with gtk gnome)
+}