net-p2p/qbittorrent: drop 5.0.0 due to vulnerability

It was never stable

Bug: https://bugs.gentoo.org/942569
Signed-off-by: Filip Kobierski <fkobi@pm.me>
Signed-off-by: Eli Schwartz <eschwartz@gentoo.org>

2 files changed, 0 insertions, 137 deletions

diff --git a/net-p2p/qbittorrent/Manifest b/net-p2p/qbittorrent/Manifest
index 02bde8735e82..ce056658813f 100644
--- a/net-p2p/qbittorrent/Manifest
+++ b/net-p2p/qbittorrent/Manifest
@@ -1,4 +1,2 @@
 DIST qbittorrent-4.6.7.tar.xz 4539016 BLAKE2B 8565fdc298e5085b10b52442874ce2d9b9f253ba57bb2d1bef065d603847e5d3d838197ea2077aa80cc3db56aea4b1100fad2d7a0398fa13128d4a064286afc6 SHA512 3664c89f91a3443c74a5c76da8f66ab595bf4f48cbba2421a287d4f8bf780e06605cd0a6fa9598a5ab09e876a46d31b2f85461ef65f17410df1914acd9d37262
 DIST qbittorrent-4.6.7.tar.xz.asc 849 BLAKE2B e63d1fc1c8c6b9a70551bd717a2614b8548bd93656b578f4289d720c2784508ca90971f995fa6c8b6dc26ed6a7f976d294e44d4e384bb3de30791f26ff930017 SHA512 820e329921d23409560fa2a2f3e714b233154783da5bb8fdcf7ed70c90df69d5140d8159f8d52dc1a9b5cc32306580a08e56c02b55f0e2b00c16cbf9f6982baa
-DIST qbittorrent-5.0.0.tar.xz 4512592 BLAKE2B 156a2aae2c45d877197d50ec0c42b003dcb290d2e612b93d94f10c1c1b55fb24d6bc37cfd489b70f545bb4f390ee35634a808992441ce49e7e27de5ecb508943 SHA512 ab480c181f3a43a3e248daa35d3d3e0b121eb80bfd8a4a4d63fd504ba26441a31e7ca563fe80bc520ad1219104cf929460cfc0a5cfdad13ad61a5a316deeb695
-DIST qbittorrent-5.0.0.tar.xz.asc 849 BLAKE2B c3fee4711f51491c26ca7669ce8746853b886334454b1b6a7ae0fb61e2634cfe3172c00f3b0ac2c1ca498b23969c3d6ac3095fbb380e9a3626a1923705a40fb3 SHA512 60589122b9030f17afa766a757992134430f7bb32ee97acc5f544dcac99f82a0fc00411d46a11c52f350790f86fa686158e06c74cc53dbabcfc96ebb5f4af09e
diff --git a/net-p2p/qbittorrent/qbittorrent-5.0.0.ebuild b/net-p2p/qbittorrent/qbittorrent-5.0.0.ebuild
deleted file mode 100644
index e40ab0f8d98e..000000000000
--- a/net-p2p/qbittorrent/qbittorrent-5.0.0.ebuild
+++ /dev/null
@@ -1,135 +0,0 @@
-# Copyright 2023-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake edo multibuild optfeature systemd verify-sig xdg
-
-DESCRIPTION="BitTorrent client in C++ and Qt"
-HOMEPAGE="https://www.qbittorrent.org"
-
-if [[ ${PV} == *9999 ]]; then
-	EGIT_REPO_URI="https://github.com/qbittorrent/qBittorrent.git"
-	inherit git-r3
-else
-	SRC_URI="
-		https://downloads.sourceforge.net/qbittorrent/${P}.tar.xz
-		verify-sig? ( https://downloads.sourceforge.net/qbittorrent/${P}.tar.xz.asc )
-	"
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
-
-	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-qbittorrent )"
-	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/qBittorrent.asc
-fi
-
-LICENSE="GPL-2+ GPL-3+"
-SLOT="0"
-IUSE="+dbus +gui systemd test webui"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="
-	|| ( gui webui )
-	dbus? ( gui )
-"
-
-RDEPEND="
-	>=dev-libs/openssl-3.0.2:=
-	>=net-libs/libtorrent-rasterbar-1.2.19:=
-	>=sys-libs/zlib-1.2.11
-	>=dev-qt/qtbase-6.5:6[network,ssl,sql,sqlite,xml]
-	gui? (
-		>=dev-qt/qtbase-6.5:6[dbus?,gui,widgets]
-		>=dev-qt/qtsvg-6.5:6
-	)
-	webui? (
-		acct-group/qbittorrent
-		acct-user/qbittorrent
-	)
-"
-DEPEND="
-	${RDEPEND}
-	>=dev-libs/boost-1.76
-"
-BDEPEND+="
-	>=dev-qt/qttools-6.5:6[linguist]
-	virtual/pkgconfig
-"
-
-DOCS=( AUTHORS Changelog CONTRIBUTING.md README.md )
-
-src_prepare() {
-	MULTIBUILD_VARIANTS=()
-	use gui && MULTIBUILD_VARIANTS+=( gui )
-	use webui && MULTIBUILD_VARIANTS+=( nogui )
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	my_src_configure() {
-		local mycmakeargs=(
-			# musl lacks execinfo.h
-			-DSTACKTRACE=$(usex !elibc_musl)
-			# More verbose build logs are preferable for bug reports
-			-DVERBOSE_CONFIGURE=ON
-			-DWEBUI=$(usex webui)
-			-DTESTING=$(usex test)
-		)
-
-		if [[ ${MULTIBUILD_VARIANT} == "gui" ]]; then
-			# We do this in multibuild, see bug #839531 for why.
-			# Fedora has to do the same thing.
-			mycmakeargs+=(
-				-DGUI=ON
-				-DDBUS=$(usex dbus)
-				-DSYSTEMD=OFF
-			)
-		else
-			mycmakeargs+=(
-				-DGUI=OFF
-				-DDBUS=OFF
-			)
-
-			use systemd && mycmakeargs+=(
-				# The systemd service calls qbittorrent-nox, which is only
-				# installed when GUI=OFF.
-				-DSYSTEMD=ON
-				-DSYSTEMD_SERVICES_INSTALL_DIR="$(systemd_get_systemunitdir)"
-			)
-		fi
-
-		cmake_src_configure
-	}
-
-	multibuild_foreach_variant my_src_configure
-}
-
-src_compile() {
-	multibuild_foreach_variant cmake_src_compile
-}
-
-src_test() {
-	my_src_test() {
-		# cmake does not detect tests by default, if you use enable_testing
-		# in a subdirectory instead of the root CMakeLists.txt
-		cd "${BUILD_DIR}"/test || die
-		edo ctest .
-	}
-
-	multibuild_foreach_variant my_src_test
-}
-
-src_install() {
-	multibuild_foreach_variant cmake_src_install
-	einstalldocs
-
-	if use webui; then
-		newconfd "${FILESDIR}/${PN}.confd" "${PN}"
-		newinitd "${FILESDIR}/${PN}.initd" "${PN}"
-	fi
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "I2P anonymyzing network support" net-vpn/i2pd net-vpn/i2p
-}