net-wireless/kismet: bump version to latest

Package-Manager: portage-2.2.27

3 files changed, 170 insertions, 2 deletions

diff --git a/net-wireless/kismet/Manifest b/net-wireless/kismet/Manifest
index 0f38cd0d17b7..feb38b4932b5 100644
--- a/net-wireless/kismet/Manifest
+++ b/net-wireless/kismet/Manifest
@@ -1 +1,2 @@
 DIST kismet-2013-03-R1.tar.gz 899372 SHA256 1c1e9f6b550de1f248363d4c9ce1d24fdc20d041ead5a53cec88eb1b07353082 SHA512 7e992f5ef3db4c5fa298bd4aabfe216668baade948b83996850c010c6c92bfa2fea37d7006a532eb6bace015624f536cc45ed8b3b3ed4a6a1cac7a137ac86d36 WHIRLPOOL 694796f7dd0f4ffd70e64d67eba30bf7b206189dadb8e773a302af9f417a8219b45e547bfcaf59db3f502e0f5ab18af6d642e66dbe8277d8af48daeb35b40843
+DIST kismet-2016-01-R1.tar.xz 703308 SHA256 162f1796996836b2d44126ccbe877a88a7f4a0e50f6729da897fc5a8ec4776b9 SHA512 cfbfb2cefd8df4a4fd09333eb6b0becd56cd7c3a1804d555d28b1d55379186e51804334560531d05e760d31e446c4b89d32ce2bd2c0705473f67f04611c0434e WHIRLPOOL 7ba136a9a138a43768c07668f92b6836d4345bb382935527e0576d5d4aedceb6135bc5b2a38fdfe5b7c488fadc17d759b0960c8cc8a461338adb3417024cb491
diff --git a/net-wireless/kismet/kismet-2016.01.1.ebuild b/net-wireless/kismet/kismet-2016.01.1.ebuild
new file mode 100644
index 000000000000..a79d076c15e4
--- /dev/null
+++ b/net-wireless/kismet/kismet-2016.01.1.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils multilib user
+
+MY_P=${P/\./-}
+MY_P=${MY_P/./-R}
+S=${WORKDIR}/${MY_P}
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://www.kismetwireless.net/${PN}.git"
+	SRC_URI=""
+	inherit git-2
+	KEYWORDS=""
+else
+	SRC_URI="http://www.kismetwireless.net/code/${MY_P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~ppc ~x86"
+fi
+
+DESCRIPTION="IEEE 802.11 wireless LAN sniffer"
+HOMEPAGE="http://www.kismetwireless.net/"
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+IUSE="+client +pcre speech +plugin-autowep +plugin-btscan plugin-dot15d4 +plugin-ptw +plugin-spectools +plugin-syslog +ruby selinux +suid"
+
+CDEPEND="net-wireless/wireless-tools
+	kernel_linux? ( sys-libs/libcap
+			dev-libs/libnl:3
+			net-libs/libpcap
+			)
+	pcre? ( dev-libs/libpcre )
+	suid? ( sys-libs/libcap )
+	client? ( sys-libs/ncurses )
+	!arm? ( speech? ( app-accessibility/flite ) )
+	ruby? ( dev-lang/ruby:* )
+	plugin-btscan? ( net-wireless/bluez )
+	plugin-dot15d4? ( virtual/libusb:0 )
+	plugin-spectools? ( net-wireless/spectools )
+"
+
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+"
+
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-kismet )
+"
+
+src_prepare() {
+	sed -i -e "s:^\(logtemplate\)=\(.*\):\1=/tmp/\2:" \
+		conf/kismet.conf.in
+
+	# Don't strip and set correct mangrp
+	sed -i -e 's| -s||g' \
+		-e 's|@mangrp@|root|g' Makefile.in
+}
+
+src_configure() {
+	econf \
+		$(use_enable client) \
+		$(use_enable pcre)
+}
+
+src_compile() {
+	emake
+
+	if use plugin-autowep; then
+		cd "${S}"/restricted-plugin-autowep
+		KIS_SRC_DIR="${S}" emake
+	fi
+	if use plugin-btscan; then
+		cd "${S}"/plugin-btscan
+		KIS_SRC_DIR="${S}" emake
+	fi
+	if use plugin-dot15d4; then
+		cd "${S}"/plugin-dot15d4
+		KIS_SRC_DIR="${S}" emake
+	fi
+	if use plugin-ptw; then
+		cd "${S}"/restricted-plugin-ptw
+		KIS_SRC_DIR="${S}" emake
+	fi
+	if use plugin-spectools; then
+		cd "${S}"/plugin-spectools
+		KIS_SRC_DIR="${S}" emake
+	fi
+	if use plugin-syslog; then
+		cd "${S}"/plugin-syslog
+		KIS_SRC_DIR="${S}" emake
+	fi
+}
+
+src_install() {
+	if use plugin-autowep; then
+		cd "${S}"/restricted-plugin-autowep
+		KIS_SRC_DIR="${S}" emake DESTDIR="${ED}" LIBDIR="$(get_libdir)" install
+	fi
+	if use plugin-btscan; then
+		cd "${S}"/plugin-btscan
+		KIS_SRC_DIR="${S}" emake DESTDIR="${ED}" LIBDIR="$(get_libdir)" install
+	fi
+	if use plugin-dot15d4; then
+		cd "${S}"/plugin-dot15d4
+		KIS_SRC_DIR="${S}" emake DESTDIR="${ED}" LIBDIR="$(get_libdir)" install
+	fi
+	if use plugin-ptw; then
+		cd "${S}"/restricted-plugin-ptw
+		KIS_SRC_DIR="${S}" emake DESTDIR="${ED}" LIBDIR="$(get_libdir)" install
+	fi
+	if use plugin-spectools; then
+		cd "${S}"/plugin-spectools
+		KIS_SRC_DIR="${S}" emake DESTDIR="${ED}" LIBDIR="$(get_libdir)" install
+	fi
+	if use plugin-syslog; then
+		cd "${S}"/plugin-syslog
+		KIS_SRC_DIR="${S}" emake DESTDIR="${ED}" LIBDIR="$(get_libdir)" install
+	fi
+	if use ruby; then
+		cd "${S}"/ruby
+		dobin *.rb
+	fi
+
+	cd "${S}"
+	emake DESTDIR="${D}" commoninstall
+
+	##dragorn would prefer I set fire to my head than do this, but it works
+	##all external kismet plugins (read: kismet-ubertooth) must be rebuilt when kismet is
+	##is there an automatic way to force this?
+	# install headers for external plugins
+	insinto /usr/include/kismet
+	doins *.h
+	doins Makefile.inc
+	#todo write a plugin finder that tells you what needs to be rebuilt when kismet is updated, etc
+
+	dodoc CHANGELOG RELEASENOTES.txt README* docs/DEVEL.client docs/README.newcore
+	newinitd "${FILESDIR}"/${PN}.initd kismet
+	newconfd "${FILESDIR}"/${PN}.confd kismet
+
+	insinto /etc
+	doins conf/kismet{,_drone}.conf
+
+	if use suid; then
+	dobin kismet_capture
+	fi
+}
+
+pkg_preinst() {
+	if use suid; then
+		enewgroup kismet
+		fowners root:kismet /usr/bin/kismet_capture
+		# Need to set the permissions after chowning.
+		# See chown(2)
+		fperms 4550 /usr/bin/kismet_capture
+		elog "Kismet has been installed with a setuid-root helper binary"
+		elog "to enable minimal-root operation.  Users need to be part of"
+		elog "the 'kismet' group to perform captures from physical devices."
+	fi
+	if ! use suid; then
+		ewarn "It is highly discouraged to run a sniffer as root,"
+		ewarn "Please consider enabling the suid use flag and adding"
+		ewarn "your user to the kismet group."
+	fi
+}
diff --git a/net-wireless/kismet/kismet-9999.ebuild b/net-wireless/kismet/kismet-9999.ebuild
index 629f220cbdd6..7837d5b33a4e 100644
--- a/net-wireless/kismet/kismet-9999.ebuild
+++ b/net-wireless/kismet/kismet-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -16,7 +16,7 @@ if [[ ${PV} == "9999" ]] ; then
 	inherit git-2
 	KEYWORDS=""
 else
-	SRC_URI="http://www.kismetwireless.net/code/${MY_P}.tar.gz"
+	SRC_URI="http://www.kismetwireless.net/code/${MY_P}.tar.xz"
 	KEYWORDS="~amd64 ~arm ~ppc ~x86"
 fi