sci-biology/phylip: Version bump to 3.698

Bug: https://bugs.gentoo.org/707150
Bug: https://bugs.gentoo.org/727982
Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 60 insertions, 0 deletions

diff --git a/sci-biology/phylip/phylip-3.698.ebuild b/sci-biology/phylip/phylip-3.698.ebuild
new file mode 100644
index 000000000000..0a8ef8f815ec
--- /dev/null
+++ b/sci-biology/phylip/phylip-3.698.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION=" The PHYLogeny Inference Package"
+HOMEPAGE="http://evolution.genetics.washington.edu/phylip.html"
+SRC_URI="http://evolution.gs.washington.edu/${PN}/download/${P}.zip"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+
+# 'mix' tool collides with dev-lang/elixir, bug #537514
+RDEPEND="
+	x11-libs/libXaw
+	!dev-lang/elixir"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="app-arch/unzip"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-makefile.patch
+	"${FILESDIR}"/${P}-fno-common.patch
+)
+
+src_prepare() {
+	default
+
+	mkdir fonts || die
+	# clear out old binaries
+	rm -r exe || die
+}
+
+src_configure() {
+	tc-export CC
+	append-cflags -Wno-unused-result
+}
+
+src_compile() {
+	emake -C src -f Makefile.unx all put
+}
+
+src_install() {
+	mv exe/font* fonts || die "Font move failed"
+	mv exe/factor exe/factor-${PN} || die "Renaming factor failed"
+
+	dolib.so exe/*so
+	rm exe/*so || die
+	dobin exe/*
+
+	dodoc "${FILESDIR}"/README.Gentoo
+	docinto html
+	dodoc -r phylip.html doc
+
+	insinto /usr/share/phylip
+	doins -r fonts
+}