sci-libs/amd: add 3.0.3

Signed-off-by: François Bissey <frp.bissey@gmail.com>
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

1 files changed, 67 insertions, 0 deletions

diff --git a/sci-libs/amd/amd-3.0.3.ebuild b/sci-libs/amd/amd-3.0.3.ebuild
new file mode 100644
index 000000000000..687a2d2554f7
--- /dev/null
+++ b/sci-libs/amd/amd-3.0.3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+FORTRAN_NEEDED="fortran"
+inherit cmake-multilib fortran-2
+
+Sparse_PV="7.0.0"
+Sparse_P="SuiteSparse-${Sparse_PV}"
+DESCRIPTION="Library to order a sparse matrix prior to Cholesky factorization"
+HOMEPAGE="https://people.engr.tamu.edu/davis/suitesparse.html"
+SRC_URI="https://github.com/DrTimothyAldenDavis/SuiteSparse/archive/refs/tags/v${Sparse_PV}.tar.gz -> ${Sparse_P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc fortran test"
+RESTRICT="!test? ( test )"
+
+DEPEND=">=sci-libs/suitesparseconfig-${Sparse_PV}"
+RDEPEND="${DEPEND}"
+BDEPEND="doc? ( virtual/latex-base )"
+
+S="${WORKDIR}/${Sparse_P}/${PN^^}"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DNSTATIC=ON
+		-DNFORTRAN=$(usex fortran OFF ON)
+		-DDEMO=$(usex test)
+	)
+	cmake_src_configure
+}
+
+multilib_src_test() {
+	# Run demo files
+	local demofiles=(
+		amd_demo
+		amd_l_demo
+		amd_demo2
+		amd_simple
+	)
+	if use fortran; then
+		demofiles+=(
+			amd_f77simple
+			amd_f77demo
+		)
+	fi
+	for i in ${demofiles}; do
+		./"${i}" > "${i}.out"
+		diff "${S}/Demo/${i}.out" "${i}.out" || die "failed testing ${i}"
+	done
+	einfo "All tests passed"
+}
+
+multilib_src_install() {
+	if use doc; then
+		pushd "${S}/Doc"
+		emake clean
+		rm -rf *.pdf
+		emake
+		popd
+		DOCS="${S}/Doc/*.pdf"
+	fi
+	cmake_src_install
+}