x11-libs/cairo: Version bump to 1.17.6

Closes: https://bugs.gentoo.org/866305
Signed-off-by: Matt Turner <mattst88@gentoo.org>

4 files changed, 158 insertions, 77 deletions

diff --git a/x11-libs/cairo/Manifest b/x11-libs/cairo/Manifest
index a9d5249c5cb1..e13c60cdc610 100644
--- a/x11-libs/cairo/Manifest
+++ b/x11-libs/cairo/Manifest
@@ -1 +1,2 @@
 DIST cairo-1.16.0.tar.xz 41997432 BLAKE2B aa37edf7fdf0c952484fd0adc9281724227db93958d6e4919216b30e9017fab670bc2340e3b975737080f1f67dec24025fe0e4680e275ab7703cfb9235eb1fe0 SHA512 9eb27c4cf01c0b8b56f2e15e651f6d4e52c99d0005875546405b64f1132aed12fbf84727273f493d84056a13105e065009d89e94a8bfaf2be2649e232b82377f
+DIST cairo-1.17.6.tar.bz2 43700076 BLAKE2B 05ac766d33e9bdfc5df0347e9a80611554d64886715d1620fbe6f05f36f0134e46e1e6107738d260b380fab5ef2ac609922dce9ebcac01234710d8e2a76e9724 SHA512 1537b34ca49b853f4f60a7ceac0c1b878e7e2874f1ca3a37ab6ccbb704a37872314447016ad07b82312b302bb6df86b71265232a802ccdb9fb8cd18f211ff185
diff --git a/x11-libs/cairo/cairo-1.17.6.ebuild b/x11-libs/cairo/cairo-1.17.6.ebuild
new file mode 100644
index 000000000000..74987be53131
--- /dev/null
+++ b/x11-libs/cairo/cairo-1.17.6.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/cairo/cairo.git"
+	SRC_URI=""
+else
+	SRC_URI="https://gitlab.freedesktop.org/cairo/cairo/-/archive/${PV}/cairo-${PV}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A vector graphics library with cross-device output support"
+HOMEPAGE="https://www.cairographics.org/ https://gitlab.freedesktop.org/cairo/cairo"
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+IUSE="X aqua debug gles2-only gles3 +glib gtk-doc opengl test"
+REQUIRED_USE="
+	gles2-only? ( !opengl )
+	gles3? ( gles2-only )
+"
+RESTRICT="!test? ( test ) test" # Requires poppler-glib, which isn't available in multilib
+
+RDEPEND="
+	>=dev-libs/lzo-2.06-r1:2[${MULTILIB_USEDEP}]
+	>=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}]
+	>=media-libs/freetype-2.5.0.1:2[png,${MULTILIB_USEDEP}]
+	>=media-libs/libpng-1.6.10:0=[${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	>=x11-libs/pixman-0.36[${MULTILIB_USEDEP}]
+	debug? ( sys-libs/binutils-libs:0=[${MULTILIB_USEDEP}] )
+	gles2-only? ( >=media-libs/mesa-9.1.6[gles2,${MULTILIB_USEDEP}] )
+	glib? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
+	opengl? ( >=media-libs/mesa-9.1.6[egl(+),X(+),${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libXrender-0.9.8[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libxcb-1.9.1:=[${MULTILIB_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-respect-fontconfig.patch
+)
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dfontconfig=enabled
+		-Dfreetype=enabled
+		-Dpng=enabled
+		$(meson_feature aqua quartz)
+		$(meson_feature X tee)
+		$(meson_feature X xcb)
+		$(meson_feature X xlib)
+		-Dxlib-xcb=disabled
+		-Dxml=disabled
+		-Dzlib=enabled
+
+		$(meson_feature test tests)
+
+		-Dgtk2-utils=disabled
+
+		$(meson_feature glib)
+		-Dspectre=disabled # only used for tests
+		$(meson_feature debug symbol-lookup)
+
+		$(meson_use gtk-doc gtk_doc)
+	)
+
+	if use opengl; then
+		emesonargs+=(-Dgl-backend=gl)
+	elif use gles2-only; then
+		if use gles3; then
+			emesonargs+=(-Dgl-backend=glesv3)
+		else
+			emesonargs+=(-Dgl-backend=glesv2)
+		fi
+	else
+		emesonargs+=(-Dgl-backend=disabled)
+	fi
+
+	meson_src_configure
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/cairo || die
+		mv "${ED}"/usr/share/gtk-doc/{html/cairo,cairo/html} || die
+		rmdir "${ED}"/usr/share/gtk-doc/html || die
+	fi
+}
diff --git a/x11-libs/cairo/cairo-9999.ebuild b/x11-libs/cairo/cairo-9999.ebuild
index 1ee8a6752f0d..74987be53131 100644
--- a/x11-libs/cairo/cairo-9999.ebuild
+++ b/x11-libs/cairo/cairo-9999.ebuild
@@ -1,41 +1,38 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-inherit flag-o-matic autotools multilib-minimal
+inherit meson-multilib
 
 if [[ ${PV} == *9999* ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://gitlab.freedesktop.org/cairo/cairo.git"
 	SRC_URI=""
 else
-	SRC_URI="https://www.cairographics.org/releases/${P}.tar.xz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	SRC_URI="https://gitlab.freedesktop.org/cairo/cairo/-/archive/${PV}/cairo-${PV}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 fi
 
 DESCRIPTION="A vector graphics library with cross-device output support"
 HOMEPAGE="https://www.cairographics.org/ https://gitlab.freedesktop.org/cairo/cairo"
 LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
 SLOT="0"
-IUSE="X aqua debug gles2-only +glib opengl static-libs +svg utils valgrind"
-# gtk-doc regeneration doesn't seem to work with out-of-source builds
-#[[ ${PV} == *9999* ]] && IUSE="${IUSE} doc" # API docs are provided in tarball, no need to regenerate
-
-# Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
-RESTRICT="test"
+IUSE="X aqua debug gles2-only gles3 +glib gtk-doc opengl test"
+REQUIRED_USE="
+	gles2-only? ( !opengl )
+	gles3? ( gles2-only )
+"
+RESTRICT="!test? ( test ) test" # Requires poppler-glib, which isn't available in multilib
 
-BDEPEND="
-	virtual/pkgconfig
-	>=sys-devel/libtool-2"
 RDEPEND="
-	>=dev-libs/lzo-2.06-r1[${MULTILIB_USEDEP}]
+	>=dev-libs/lzo-2.06-r1:2[${MULTILIB_USEDEP}]
 	>=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}]
 	>=media-libs/freetype-2.5.0.1:2[png,${MULTILIB_USEDEP}]
 	>=media-libs/libpng-1.6.10:0=[${MULTILIB_USEDEP}]
-	sys-libs/binutils-libs:0=[${MULTILIB_USEDEP}]
 	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
-	>=x11-libs/pixman-0.36.0[${MULTILIB_USEDEP}]
+	>=x11-libs/pixman-0.36[${MULTILIB_USEDEP}]
+	debug? ( sys-libs/binutils-libs:0=[${MULTILIB_USEDEP}] )
 	gles2-only? ( >=media-libs/mesa-9.1.6[gles2,${MULTILIB_USEDEP}] )
 	glib? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
 	opengl? ( >=media-libs/mesa-9.1.6[egl(+),X(+),${MULTILIB_USEDEP}] )
@@ -43,79 +40,61 @@ RDEPEND="
 		>=x11-libs/libXrender-0.9.8[${MULTILIB_USEDEP}]
 		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
 		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
-		>=x11-libs/libxcb-1.9.1[${MULTILIB_USEDEP}]
+		>=x11-libs/libxcb-1.9.1:=[${MULTILIB_USEDEP}]
 	)"
 DEPEND="${RDEPEND}
 	X? ( x11-base/xorg-proto )"
-#[[ ${PV} == *9999* ]] && DEPEND="${DEPEND}
-#	doc? (
-#		>=dev-util/gtk-doc-1.6
-#		~app-text/docbook-xml-dtd-4.2
-#	)"
-
-REQUIRED_USE="
-	gles2-only? ( !opengl )
-"
+BDEPEND="virtual/pkgconfig"
 
 PATCHES=(
-	"${FILESDIR}"/${PN}-1.12.18-disable-test-suite.patch
 	"${FILESDIR}"/${PN}-respect-fontconfig.patch
 )
 
-src_prepare() {
-	default
-
-	# tests and perf tools require X, bug #483574
-	if ! use X; then
-		sed -e '/^SUBDIRS/ s#boilerplate test perf# #' -i Makefile.am || die
-	fi
-
-	# Slightly messed build system YAY
-	if [[ ${PV} == *9999* ]]; then
-		touch boilerplate/Makefile.am.features
-		touch src/Makefile.am.features
-		touch ChangeLog
-	fi
-
-	eautoreconf
-}
-
 multilib_src_configure() {
-	local myopts
-
-	[[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
-
-	# [[ ${PV} == *9999* ]] && myopts+=" $(use_enable doc gtk-doc)"
+	local emesonargs=(
+		-Dfontconfig=enabled
+		-Dfreetype=enabled
+		-Dpng=enabled
+		$(meson_feature aqua quartz)
+		$(meson_feature X tee)
+		$(meson_feature X xcb)
+		$(meson_feature X xlib)
+		-Dxlib-xcb=disabled
+		-Dxml=disabled
+		-Dzlib=enabled
+
+		$(meson_feature test tests)
+
+		-Dgtk2-utils=disabled
+
+		$(meson_feature glib)
+		-Dspectre=disabled # only used for tests
+		$(meson_feature debug symbol-lookup)
+
+		$(meson_use gtk-doc gtk_doc)
+	)
+
+	if use opengl; then
+		emesonargs+=(-Dgl-backend=gl)
+	elif use gles2-only; then
+		if use gles3; then
+			emesonargs+=(-Dgl-backend=glesv3)
+		else
+			emesonargs+=(-Dgl-backend=glesv2)
+		fi
+	else
+		emesonargs+=(-Dgl-backend=disabled)
+	fi
 
-	ECONF_SOURCE="${S}" \
-	econf \
-		$(use_with X x) \
-		$(use_enable X tee) \
-		$(use_enable X xlib) \
-		$(use_enable X xlib-xrender) \
-		$(use_enable X xcb) \
-		$(use_enable X xcb-shm) \
-		$(use_enable aqua quartz) \
-		$(use_enable aqua quartz-image) \
-		$(use_enable debug test-surfaces) \
-		$(use_enable gles2-only glesv2) \
-		$(use_enable glib gobject) \
-		$(use_enable opengl gl) \
-		$(use_enable static-libs static) \
-		$(use_enable svg) \
-		$(use_enable utils trace) \
-		$(use_enable valgrind) \
-		--enable-ft \
-		--enable-interpreter \
-		--enable-pdf \
-		--enable-png \
-		--enable-ps \
-		--enable-script \
-		--disable-xlib-xcb \
-		${myopts}
+	meson_src_configure
 }
 
 multilib_src_install_all() {
-	find "${D}" -name '*.la' -delete || die
 	einstalldocs
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/cairo || die
+		mv "${ED}"/usr/share/gtk-doc/{html/cairo,cairo/html} || die
+		rmdir "${ED}"/usr/share/gtk-doc/html || die
+	fi
 }
diff --git a/x11-libs/cairo/metadata.xml b/x11-libs/cairo/metadata.xml
index 367ff5bc5dfa..d4c30a5b0bff 100644
--- a/x11-libs/cairo/metadata.xml
+++ b/x11-libs/cairo/metadata.xml
@@ -8,6 +8,7 @@
 	<use>
 		<flag name="opengl" restrict="&gt;=x11-libs/cairo-1.10.0">Build the OpenGL backend</flag>
 		<flag name="gles2-only">Build the OpenGL ES 2 backend</flag>
+		<flag name="gles3" restrict=">=x11-libs/cairo-1.17">Use OpenGL ES 3.0 features (instead of ES 2.0; requires USE=gles2-only)</flag>
 		<flag name="glib">Compile with GLib Object System support</flag>
 		<flag name="utils">Build support for Cairo script and trace utilities</flag>
 		<flag name="valgrind">Built-in support to mark memory regions</flag>