xfce-extra/xfce4-notifyd: Bump to 0.9.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/xfce-extra/xfce4-notifyd/Manifest b/xfce-extra/xfce4-notifyd/Manifest
index 08ccb7d0e678..70394643d688 100644
--- a/xfce-extra/xfce4-notifyd/Manifest
+++ b/xfce-extra/xfce4-notifyd/Manifest
@@ -1 +1,2 @@
 DIST xfce4-notifyd-0.9.2.tar.bz2 728345 BLAKE2B bcca7ea3afc8bf421fb7e48f4f9c171a7ffd772189a614e9114a5514b1a34f3aee109b40894f75053f36d0d5b6e8bdb43a7bdffb091852cc30ef7bdcb2ed91e9 SHA512 7c65111d888f4aeee7d36f3c44ca35fb7c4b0f433dd77cb9c1ae03472fd31a2b36f5bba7f6f6fafb5dbf8c60a14a09b05443f3e8ffa737fced1e8bc67278b30d
+DIST xfce4-notifyd-0.9.4.tar.bz2 732160 BLAKE2B d0c47875acf638f44ae8188c7a39f1785a9e3c489f4fad209e9c591780a91b0439037a0c62351619f71d2765dacf11a786d5678c03ec846f4aa0a0bc0b823166 SHA512 d3339ec3555f27e624e643b52ce4de2a0834d38f675b286976abcb4e143cbbb32665b1f36fbff23791c152e1f0616b752a7f049045fc32829c27c0a87d82df94
diff --git a/xfce-extra/xfce4-notifyd/xfce4-notifyd-0.9.4.ebuild b/xfce-extra/xfce4-notifyd/xfce4-notifyd-0.9.4.ebuild
new file mode 100644
index 000000000000..f1b06c391860
--- /dev/null
+++ b/xfce-extra/xfce4-notifyd/xfce4-notifyd-0.9.4.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Notification daemon for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/apps/notifyd/start
+	https://gitlab.xfce.org/apps/xfce4-notifyd/
+"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="sound wayland X"
+
+DEPEND="
+	>=dev-db/sqlite-3.34:3
+	>=dev-libs/glib-2.68.0:2
+	>=sys-apps/dbus-1.0
+	>=x11-libs/gtk+-3.22:3[wayland?,X?]
+	>=x11-libs/libnotify-0.7
+	>=xfce-base/libxfce4ui-4.12:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.12:=
+	>=xfce-base/xfce4-panel-4.14.0:=
+	>=xfce-base/xfconf-4.10:=
+	sound? (
+		>=media-libs/libcanberra-0.30[gtk3]
+	)
+	wayland? (
+		>=gui-libs/gtk-layer-shell-0.7.0
+	)
+	X? (
+		>=x11-libs/libX11-1.6.7
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable wayland)
+		$(use_enable X x11)
+
+		# just service files
+		--enable-systemd
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}