1 files changed, 50 insertions, 0 deletions
diff --git a/app-emacs/magit/magit-4.1.0.ebuild b/app-emacs/magit/magit-4.1.0.ebuild
new file mode 100644
index 000000000000..19d51447f288
--- /dev/null
+++ b/app-emacs/magit/magit-4.1.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp
+
+DESCRIPTION="A Git porcelain inside Emacs"
+HOMEPAGE="https://magit.vc/
+	https://github.com/magit/magit/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+S="${WORKDIR}/${P}/lisp"
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+DOCS=( ../README.md ../docs/AUTHORS.md ../docs/RelNotes )
+ELISP_TEXINFO="../docs/*.texi"
+SITEFILE="50${PN}-gentoo.el"
+
+RDEPEND="
+	>=app-emacs/compat-30.0.0.0
+	>=app-emacs/dash-2.19.1
+	>=app-emacs/transient-0.7.4
+	>=app-emacs/with-editor-3.4.1
+"
+BDEPEND="
+	${RDEPEND}
+	sys-apps/texinfo
+"
+RDEPEND+="
+	>=dev-vcs/git-2.44.2
+"
+
+src_prepare() {
+	default
+
+	echo "(setq ${PN}-version \"${PV}\")" > ./${PN}-version.el || die
+}