1 files changed, 56 insertions, 0 deletions
diff --git a/app-text/zathura-cb/zathura-cb-0.1.4.ebuild b/app-text/zathura-cb/zathura-cb-0.1.4.ebuild
new file mode 100644
index 000000000000..2347b3176202
--- /dev/null
+++ b/app-text/zathura-cb/zathura-cb-0.1.4.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils toolchain-funcs
+[[ ${PV} == 9999* ]] && inherit git-2
+
+DESCRIPTION="Comic book plug-in for zathura with 7zip, rar, tar and zip support"
+HOMEPAGE="http://pwmt.org/projects/zathura/"
+if ! [[ ${PV} == 9999* ]]; then
+SRC_URI="http://pwmt.org/projects/zathura/plugins/download/${P}.tar.gz"
+fi
+EGIT_REPO_URI="git://git.pwmt.org/${PN}.git"
+EGIT_BRANCH="develop"
+
+LICENSE="ZLIB"
+SLOT="0"
+if ! [[ ${PV} == 9999* ]]; then
+KEYWORDS="~amd64 ~arm ~x86"
+else
+KEYWORDS=""
+fi
+IUSE=""
+
+COMMON_DEPEND=">=app-text/zathura-0.3.1
+	dev-libs/glib:2=
+	app-arch/libarchive:=
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:="
+RDEPEND="${COMMON_DEPEND}
+	app-arch/p7zip
+	app-arch/tar
+	app-arch/unrar
+	app-arch/unzip"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig"
+
+pkg_setup() {
+	myzathuraconf=(
+		CC="$(tc-getCC)"
+		LD="$(tc-getLD)"
+		VERBOSE=1
+		DESTDIR="${D}"
+	)
+}
+
+src_compile() {
+	emake "${myzathuraconf[@]}"
+}
+
+src_install() {
+	emake "${myzathuraconf[@]}" install
+	dodoc AUTHORS
+}