1 files changed, 36 insertions, 0 deletions
diff --git a/dev-ml/menhir/menhir-20181006.ebuild b/dev-ml/menhir/menhir-20181006.ebuild
new file mode 100644
index 000000000000..1ae3f25522f1
--- /dev/null
+++ b/dev-ml/menhir/menhir-20181006.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit findlib eutils
+
+DESCRIPTION="LR(1) parser generator for the OCaml language"
+HOMEPAGE="http://gallium.inria.fr/~fpottier/menhir/"
+SRC_URI="http://gallium.inria.fr/~fpottier/menhir/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2-with-linking-exception"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+IUSE="examples +ocamlopt"
+
+RDEPEND=">=dev-lang/ocaml-4.02:=[ocamlopt?]"
+DEPEND="${RDEPEND}
+	dev-ml/ocamlbuild"
+
+src_configure() {
+	if ! use ocamlopt ; then
+		export TARGET=byte
+	fi
+}
+
+src_compile() {
+	emake PREFIX="${EPREFIX}"/usr -j1
+}
+
+src_install() {
+	findlib_src_preinst
+	emake PREFIX="${ED}"/usr docdir="${ED}"/usr/share/doc/"${PF}" $(use examples || echo "DOCS=manual.pdf") install
+	use examples && docompress -x /usr/share/doc/${PF}/demos
+	dodoc README.md CHANGES.md
+}