1 files changed, 62 insertions, 0 deletions
diff --git a/dev-python/stevedore/stevedore-1.20.0.ebuild b/dev-python/stevedore/stevedore-1.20.0.ebuild
new file mode 100644
index 000000000000..091165f121e6
--- /dev/null
+++ b/dev-python/stevedore/stevedore-1.20.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Manage dynamic plugins for Python applications"
+HOMEPAGE="https://github.com/openstack/stevedore https://pypi.python.org/pypi/stevedore"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND=">=dev-python/pbr-1.8[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/coverage-4.0[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-sphinx-4.7.0[${PYTHON_USEDEP}]
+		>=dev-python/reno-1.8.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/pillow-2.4.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.4[${PYTHON_USEDEP}]
+		>=dev-python/oslo-sphinx-4.7.0[${PYTHON_USEDEP}]
+		>=dev-python/reno-1.8.0[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	# Delete spurious data in requirements.txt
+	sed -e '/^pbr/d' -i requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	nosetests --verbosity=3 stevedore || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}