1 files changed, 55 insertions, 0 deletions
diff --git a/dev-python/tempora/tempora-2.0.0.ebuild b/dev-python/tempora/tempora-2.0.0.ebuild
new file mode 100644
index 000000000000..cd400083854e
--- /dev/null
+++ b/dev-python/tempora/tempora-2.0.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6,7,8} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Objects and routines pertaining to date and time"
+HOMEPAGE="https://github.com/jaraco/tempora"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc64 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/jaraco-functools-1.20[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+
+python_prepare_all() {
+	# avoid a setuptools_scm dependency
+	sed -i "s:use_scm_version=True:version='${PV}',name='${PN//-/.}':" setup.py || die
+	sed -r -i "s:setuptools_scm[[:space:]]*([><=]{1,2}[[:space:]]*[0-9.a-zA-Z]+)[[:space:]]*::" \
+		setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	# Skip a test that requires pytest-freezegun
+	# because it seems to be poorly maintained
+	PYTHONPATH=. pytest -vv --override-ini="addopts=--doctest-modules" \
+		--deselect tempora/__init__.py::tempora.get_nearest_year_for_day \
+		|| die "tests failed with ${EPYTHON}"
+}