1 files changed, 42 insertions, 0 deletions
diff --git a/dev-qt/qtprintsupport/qtprintsupport-5.15.0.ebuild b/dev-qt/qtprintsupport/qtprintsupport-5.15.0.ebuild
new file mode 100644
index 000000000000..5945c013cb24
--- /dev/null
+++ b/dev-qt/qtprintsupport/qtprintsupport-5.15.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+QT5_MODULE="qtbase"
+VIRTUALX_REQUIRED="test"
+inherit qt5-build
+
+DESCRIPTION="Printing support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+IUSE="cups gles2-only"
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}:5=
+	~dev-qt/qtgui-${PV}[gles2-only=]
+	~dev-qt/qtwidgets-${PV}[gles2-only=]
+	cups? ( >=net-print/cups-1.4 )
+"
+DEPEND="${RDEPEND}
+	test? ( ~dev-qt/qtnetwork-${PV} )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/printsupport
+	src/plugins/printsupport
+)
+
+QT5_GENTOO_CONFIG=(
+	cups
+)
+
+src_configure() {
+	local myconf=(
+		$(qt_use cups)
+		-opengl $(usex gles2-only es2 desktop)
+	)
+	qt5-build_src_configure
+}