1 files changed, 35 insertions, 0 deletions
diff --git a/dev-ruby/webrobots/webrobots-0.1.2.ebuild b/dev-ruby/webrobots/webrobots-0.1.2.ebuild
new file mode 100644
index 000000000000..eaf85376364a
--- /dev/null
+++ b/dev-ruby/webrobots/webrobots-0.1.2.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+USE_RUBY="ruby20 ruby21 ruby22"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_DOCDIR="rdoc"
+RUBY_FAKEGEM_EXTRADOC="README.rdoc"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A library to help write robots.txt compliant web robots"
+HOMEPAGE="https://github.com/knu/webrobots"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE=""
+
+ruby_add_rdepend ">=dev-ruby/nokogiri-1.4.4"
+
+ruby_add_bdepend "test? ( dev-ruby/shoulda dev-ruby/test-unit:2 dev-ruby/webmock )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/,/end/d' Rakefile test/helper.rb || die
+
+	# Avoid tests for live websites requirering a network connection.
+	sed -i -e '/robots.txt in the real world/,/^  end/ s:^:#:' test/test_webrobots.rb || die
+}
+
+each_ruby_test() {
+	ruby-ng_testrb-2 -Ilib test/test_*.rb
+}