1 files changed, 44 insertions, 0 deletions
diff --git a/kde-apps/libkleo/libkleo-21.08.3-r1.ebuild b/kde-apps/libkleo/libkleo-21.08.3-r1.ebuild
new file mode 100644
index 000000000000..7df3eca6ded6
--- /dev/null
+++ b/kde-apps/libkleo/libkleo-21.08.3-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.84.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Library for encryption handling"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="amd64 arm64 ~ppc64 ~riscv x86"
+IUSE="+fancyviewer"
+
+RDEPEND="
+	>=app-crypt/gpgme-1.16.0:=[cxx,qt5]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	fancyviewer? ( >=kde-apps/kpimtextedit-${PVCUT}:5 )
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package fancyviewer KF5PimTextEdit)
+	)
+
+	ecm_src_configure
+}