1 files changed, 0 insertions, 73 deletions
diff --git a/media-libs/libmediaart/libmediaart-1.9.4.ebuild b/media-libs/libmediaart/libmediaart-1.9.4.ebuild
deleted file mode 100644
index 1d664b0ef6e9..000000000000
--- a/media-libs/libmediaart/libmediaart-1.9.4.ebuild
+++ /dev/null
@@ -1,73 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="6"
-
-VALA_USE_DEPEND="vapigen"
-VALA_MIN_API_VERSION="0.16"
-
-inherit autotools gnome2 vala virtualx
-
-DESCRIPTION="Manages, extracts and handles media art caches"
-HOMEPAGE="https://gitlab.gnome.org/GNOME/libmediaart"
-
-LICENSE="LGPL-2.1+"
-SLOT="2.0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc x86"
-IUSE="gtk +introspection qt5 vala"
-REQUIRED_USE="
-	?? ( gtk qt5 )
-	vala? ( introspection )
-"
-
-RDEPEND="
-	>=dev-libs/glib-2.38.0:2
-	gtk? ( >=x11-libs/gdk-pixbuf-2.12:2 )
-	introspection? ( >=dev-libs/gobject-introspection-1.30:= )
-	qt5? ( dev-qt/qtgui:5 )
-"
-DEPEND="${RDEPEND}
-	dev-libs/gobject-introspection-common
-	>=dev-util/gtk-doc-am-1.8
-	virtual/pkgconfig
-	vala? ( $(vala_depend) )
-"
-
-src_prepare() {
-	# Make doc parallel installable
-	cd "${S}"/docs/reference/${PN} || die
-	sed -e "s/\(DOC_MODULE.*=\).*/\1${PN}-${SLOT}/" \
-		-e "s/\(DOC_MAIN_SGML_FILE.*=\).*/\1${PN}-docs-${SLOT}.xml/" \
-		-i Makefile.am Makefile.in || die
-	sed -e "s/\(<book.*name=\"\)libmediaart/\1${PN}-${SLOT}/" \
-		-i html/libmediaart.devhelp2 || die
-	mv libmediaart-docs{,-${SLOT}}.xml || die
-	mv libmediaart-overrides{,-${SLOT}}.txt || die
-	mv libmediaart-sections{,-${SLOT}}.txt || die
-	mv html/libmediaart{,-${SLOT}}.devhelp2 || die
-	cd "${S}" || die
-
-	eapply "${FILESDIR}"/${PN}-1.9.4-drop-bashisms-configure.patch
-	eautoreconf
-
-	use vala && vala_src_prepare
-	gnome2_src_prepare
-}
-
-src_configure() {
-	if use qt5 ; then
-		local myconf="--with-qt-version=5"
-	fi
-
-	gnome2_src_configure \
-		--enable-unit-tests \
-		$(use_enable gtk gdkpixbuf) \
-		$(use_enable introspection) \
-		$(use_enable qt5 qt) \
-		$(use_enable vala) \
-		${myconf}
-}
-
-src_test() {
-	dbus-launch virtx emake check #513502
-}