1 files changed, 47 insertions, 0 deletions
diff --git a/x11-misc/snixembed/snixembed-0.2.2.ebuild b/x11-misc/snixembed/snixembed-0.2.2.ebuild
new file mode 100644
index 000000000000..aaec6ff02216
--- /dev/null
+++ b/x11-misc/snixembed/snixembed-0.2.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit vala
+
+DESCRIPTION="Proxy StatusNotifierItems as XEmbedded systemtray-spec icons"
+HOMEPAGE="https://git.sr.ht/~steef/snixembed"
+SRC_URI="https://git.sr.ht/~steef/snixembed/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc"
+
+DEPEND="dev-libs/glib:2
+	dev-libs/libdbusmenu[gtk3]
+	x11-libs/gtk+:3"
+RDEPEND="${DEPEND}"
+BDEPEND="$(vala_depend)
+	virtual/pkgconfig
+	doc? ( dev-lang/vala[valadoc] )"
+
+src_prepare() {
+	default
+
+	use doc && local VALA_USE_DEPEND="valadoc"
+	vala_src_prepare
+
+	sed -e "s: .git/HEAD .git/index::" \
+		-e "s:\$(shell git describe --always --tags --dirty):${PV}:" \
+		-e "s:valac :${VALAC} :" \
+		-e "s:valadoc :${VALADOC} :" \
+		-i makefile || die
+}
+
+src_compile() {
+	default
+	use doc && emake doc
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}" BINDIR="/usr/bin" install
+	use doc && HTML_DOCS=( doc/. )
+	einstalldocs
+}