blob: a7f45aa66b78c8245701e7f7d9c935d85d45571b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
VALA_USE_DEPEND="vapigen"
PYTHON_COMPAT=( python2_7 )
inherit autotools eutils ltprune multilib-minimal python-single-r1 vala xdg-utils
DESCRIPTION="A library to allow applications to export a menu into the Unity Menu bar"
HOMEPAGE="https://launchpad.net/libappindicator"
SRC_URI="https://launchpad.net/${PN}/${PV%.*}/${PV}/+download/${P}.tar.gz"
LICENSE="LGPL-2.1 LGPL-3"
SLOT="2"
KEYWORDS="amd64 ~arm x86"
IUSE="+introspection python"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
>=dev-libs/dbus-glib-0.98[${MULTILIB_USEDEP}]
>=dev-libs/glib-2.26:2[${MULTILIB_USEDEP}]
>=dev-libs/libdbusmenu-0.6.2[gtk,${MULTILIB_USEDEP}]
>=dev-libs/libindicator-12.10.0:0[${MULTILIB_USEDEP}]
x11-libs/gtk+:2[${MULTILIB_USEDEP},introspection?]
introspection? ( >=dev-libs/gobject-introspection-1:= )
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/pygtk[${PYTHON_MULTI_USEDEP}]
')
)
"
DEPEND="${RDEPEND}
virtual/pkgconfig[${MULTILIB_USEDEP}]
introspection? ( $(vala_depend) )
"
PATCHES=(
"${FILESDIR}"/${P}-conditional-py-bindings.patch
# http://bazaar.launchpad.net/~indicator-applet-developers/libappindicator/trunk.12.10/revision/244
"${FILESDIR}"/${P}-vala-inherit.patch
)
pkg_setup() {
use python && python-single-r1_pkg_setup
export MAKEOPTS+=" -j1" #638782
}
src_prepare() {
default
xdg_environment_reset
# Don't use -Werror
sed -i -e 's/ -Werror//' {src,tests}/Makefile.{am,in} || die
eautoreconf
# Disable MONO for now because of https://bugs.gentoo.org/382491
sed -i -e '/^MONO_REQUIRED_VERSION/s:=.*:=9999:' configure || die
}
multilib_src_configure() {
if multilib_is_native_abi; then
local -x VALAC VALA_API_GEN VAPIGEN_VAPIDIR PKG_CONFIG_PATH
use introspection && vala_src_prepare && export VALA_API_GEN="${VAPIGEN}"
fi
ECONF_SOURCE=${S} \
econf \
--disable-static \
--with-gtk=2 \
$(multilib_native_use_enable introspection) \
$(multilib_native_use_enable python)
}
multilib_src_install() {
emake -j1 DESTDIR="${D}" install
}
multilib_src_install_all() {
einstalldocs
prune_libtool_files --modules
# installed by slot 3 as well
rm -r "${D}"usr/share/gtk-doc || die
}
|
GitWeb