blob: 05bce9a84d29922e849d90521d2827d4040bcc67 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Copyright 2014-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit meson optfeature python-any-r1 udev
DESCRIPTION="Library to handle input devices in Wayland"
HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/${PV}/${P}.tar.bz2"
LICENSE="MIT"
SLOT="0/10"
if [[ $(ver_cut 3) -lt 900 ]] ; then
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ppc64 ~riscv ~s390 sparc x86"
fi
IUSE="doc input_devices_wacom test"
RESTRICT="!test? ( test )"
RDEPEND="
input_devices_wacom? ( >=dev-libs/libwacom-0.27:= )
>=dev-libs/libevdev-1.9.902
>=sys-libs/mtdev-1.1
virtual/libudev:=
virtual/udev
"
DEPEND="
${RDEPEND}
test? ( >=dev-libs/check-0.9.10 )
"
BDEPEND="
virtual/pkgconfig
doc? (
$(python_gen_any_dep '
dev-python/commonmark[${PYTHON_USEDEP}]
dev-python/recommonmark[${PYTHON_USEDEP}]
dev-python/sphinx[${PYTHON_USEDEP}]
>=dev-python/sphinx-rtd-theme-0.2.4[${PYTHON_USEDEP}]
')
>=app-text/doxygen-1.8.3
>=media-gfx/graphviz-2.38.0
)
test? (
$(python_gen_any_dep '
dev-python/pytest[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
')
)
"
# test? ( dev-debug/valgrind )
python_check_deps() {
if use doc; then
python_has_version \
"dev-python/commonmark[${PYTHON_USEDEP}]" \
"dev-python/recommonmark[${PYTHON_USEDEP}]" \
"dev-python/sphinx[${PYTHON_USEDEP}]" \
">=dev-python/sphinx-rtd-theme-0.2.4[${PYTHON_USEDEP}]" \
|| return
fi
if use test; then
python_has_version \
"dev-python/pytest[${PYTHON_USEDEP}]" \
"dev-python/pytest-xdist[${PYTHON_USEDEP}]" \
|| return
fi
}
src_prepare() {
default
sed "s@, '-Werror'@@" -i meson.build || die #744250
}
src_configure() {
# gui can be built but will not be installed
local emesonargs=(
-Ddebug-gui=false
$(meson_use doc documentation)
$(meson_use input_devices_wacom libwacom)
$(meson_use test tests)
-Dudev-dir="${EPREFIX}$(get_udevdir)"
)
meson_src_configure
}
src_install() {
meson_src_install
if use doc ; then
docinto html
dodoc -r "${BUILD_DIR}"/Documentation/.
fi
}
pkg_postinst() {
optfeature "measure and replay tools" dev-python/libevdev
udev_reload
}
pkg_postrm() {
udev_reload
}
|
GitWeb