blob: 88ba4d121db3f5c759dbf1069ebaf04fb3b774ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
|
# Copyright 2014-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="8"
PYTHON_COMPAT=( python3_{9..10} )
DISTUTILS_OPTIONAL="1"
inherit autotools distutils-r1 toolchain-funcs
if [[ "${PV}" == "9999" ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/s-yata/marisa-trie"
fi
DESCRIPTION="Matching Algorithm with Recursively Implemented StorAge"
HOMEPAGE="https://github.com/s-yata/marisa-trie https://code.google.com/archive/p/marisa-trie/"
if [[ "${PV}" == "9999" ]]; then
SRC_URI=""
else
SRC_URI="https://github.com/s-yata/marisa-trie/archive/v${PV}.tar.gz -> ${P}.tar.gz"
fi
LICENSE="|| ( BSD-2 LGPL-2.1+ )"
SLOT="0"
KEYWORDS="amd64 arm64 ~hppa ~loong ppc ppc64 ~riscv sparc x86"
IUSE="python static-libs"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
BDEPEND="python? (
${PYTHON_DEPS}
dev-lang/swig
)"
DEPEND="python? ( ${PYTHON_DEPS} )"
RDEPEND="${DEPEND}"
if [[ "${PV}" != "9999" ]]; then
S="${WORKDIR}/marisa-trie-${PV}"
fi
PATCHES=(
"${FILESDIR}/${PN}-0.2.6-riscv_word_size.patch"
"${FILESDIR}/${PN}-0.2.6-loong_word_size.patch"
"${FILESDIR}/${PN}-0.2.6-sparc64_word_size.patch"
)
src_prepare() {
default
eautoreconf
sed -e "s:^\([[:space:]]*\)libraries=:\1include_dirs=[\"../../include\"],\n\1library_dirs=[\"../../lib/marisa/.libs\"],\n&:" -i bindings/python/setup.py || die
if use python; then
pushd bindings/python > /dev/null || die
distutils-r1_src_prepare
popd > /dev/null || die
fi
}
src_configure() {
local -x CPPFLAGS="${CPPFLAGS} ${CXXFLAGS}"
cpu_instructions_option() {
local option="${1}"
local macros="${2}"
local result="--enable-${option}"
local macro
for macro in ${macros}; do
if ! $(tc-getCC) ${CPPFLAGS} ${CFLAGS} -E -P -dM - < /dev/null 2> /dev/null | grep -Eq "^#define ${macro}([[:space:]]|$)"; then
result="--disable-${option}"
fi
done
echo "${result}"
}
local options=(
$(cpu_instructions_option sse2 __SSE2__)
$(cpu_instructions_option sse3 __SSE3__)
$(cpu_instructions_option ssse3 __SSSE3__)
$(cpu_instructions_option sse4.1 __SSE4_1__)
$(cpu_instructions_option sse4.2 __SSE4_2__)
$(cpu_instructions_option sse4 __POPCNT__ __SSE4_2__)
$(cpu_instructions_option sse4a __SSE4A__)
$(cpu_instructions_option popcnt __POPCNT__)
$(cpu_instructions_option bmi __BMI__)
$(cpu_instructions_option bmi2 __BMI2__)
$(use_enable static-libs static)
)
econf "${options[@]}"
if use python; then
pushd bindings/python > /dev/null || die
distutils-r1_src_configure
popd > /dev/null || die
fi
}
src_compile() {
default
if use python; then
emake -C bindings swig-python
pushd bindings/python > /dev/null || die
distutils-r1_src_compile
popd > /dev/null || die
fi
}
src_install() {
default
find "${ED}" -name "*.la" -delete || die
(
docinto html
dodoc docs/*
)
if use python; then
pushd bindings/python > /dev/null || die
distutils-r1_src_install
popd > /dev/null || die
fi
}
|
GitWeb