blob: 159956c1f92f72cc7975bca08376463482e73729 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..9} )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1
TEST_P=GitPython-${PV}
GITDB_P=gitdb-4.0.7
SMMAP_P=smmap-4.0.0
DESCRIPTION="Library used to interact with Git repositories"
HOMEPAGE="https://github.com/gitpython-developers/GitPython https://pypi.org/project/GitPython/"
SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz
test? (
https://dev.gentoo.org/~mgorny/dist/${TEST_P}.gitbundle
https://dev.gentoo.org/~mgorny/dist/${GITDB_P}.gitbundle
https://dev.gentoo.org/~mgorny/dist/${SMMAP_P}.gitbundle
)"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
RDEPEND="
dev-vcs/git
>=dev-python/gitdb-4.0.1[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
dev-python/typing-extensions[${PYTHON_USEDEP}]
' python3_7)"
BDEPEND="
test? (
>=dev-python/ddt-1.1.1[${PYTHON_USEDEP}]
)"
distutils_enable_tests unittest
src_test() {
git config --global user.email "travis@ci.com" || die
git config --global user.name "Travis Runner" || die
git clone "${DISTDIR}/${TEST_P}.gitbundle" "${T}"/test || die
git clone "${DISTDIR}/${GITDB_P}.gitbundle" \
"${T}"/test/git/ext/gitdb || die
git clone "${DISTDIR}/${SMMAP_P}.gitbundle" \
"${T}"/test/git/ext/gitdb/gitdb/ext/smmap || die
cd "${T}"/test || die
git rev-parse HEAD > .git/refs/remotes/origin/master || die
TRAVIS=1 ./init-tests-after-clone.sh || die
cat test/fixtures/.gitconfig >> ~/.gitconfig || die
rm -r test/performance || die
# tests requiring network access
sed -i -e 's:test_fetch_error:_&:' test/test_remote.py || die
sed -i -e 's:test_leaking_password_in_clone_logs:_&:' test/test_repo.py || die
# TODO
sed -e 's:test_root_module:_&:' \
-e 's:test_base_rw:_&:' \
-i test/test_submodule.py || die
rm test/test_installation.py || die
distutils-r1_src_test
}
|
GitWeb
