blob: 9c1bb8b2cbf563b46a23849e2fda57ec39027ba3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit distutils-r1
DESCRIPTION="eGenix utils for Python"
HOMEPAGE="https://www.egenix.com/products/python/mxBase https://pypi.org/project/egenix-mx-base"
SRC_URI="https://downloads.egenix.com/python/${P}.tar.gz"
LICENSE="eGenixPublic-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE=""
# Correct broken tests
PATCHES=( "${FILESDIR}"/${PN}-3.2.6-tests.patch )
python_prepare_all() {
# Don't install documentation in site-packages directories.
sed -e "/\.pdf/d" -i egenix_mx_base.py || die
distutils-r1_python_prepare_all
}
python_compile() {
if ! python_is_python3; then
local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
fi
distutils-r1_python_compile
}
python_test() {
local t
while IFS= read -r -d '' t
do
"${PYTHON}" "${t}" || die "${t} failed with ${EPYTHON}"
done < <(find -name test.py -print0)
}
python_install() {
local f dest=${D}$(python_get_includedir)/mx
distutils-r1_python_install \
build --build-platlib "${BUILD_DIR}"/lib
mkdir -p "${dest}" || die
while IFS= read -r -d '' f
do
mv -f "${f}" "${dest}" || die
done < <(find "${D}$(python_get_sitedir)/mx" -type f -name "*.h" -print0)
}
python_install_all() {
local f
distutils-r1_python_install_all
dohtml -a html -r mx
while IFS= read -r -d '' f
do
dodoc "${f}"
done < <(find -name '*.pdf' -print0)
}
|
GitWeb
