blob: 8a318a5326c53f706124639a3ef3231d5e448c99 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( pypy3 python3_{10..12} )
inherit distutils-r1 pypi
DESCRIPTION="Core services, APIs, and REST endpoints to Jupyter web applications"
HOMEPAGE="
https://jupyter.org/
https://github.com/jupyter-server/jupyter_server/
https://pypi.org/project/jupyter-server/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~sparc ~x86"
RDEPEND="
>=dev-python/anyio-3.1.0[${PYTHON_USEDEP}]
dev-python/argon2-cffi[${PYTHON_USEDEP}]
dev-python/jinja[${PYTHON_USEDEP}]
>=dev-python/jupyter-client-7.4.4[${PYTHON_USEDEP}]
>=dev-python/jupyter-core-5.1.0[${PYTHON_USEDEP}]
dev-python/jupyter-server-terminals[${PYTHON_USEDEP}]
>=dev-python/jupyter-events-0.9.0[${PYTHON_USEDEP}]
>=dev-python/nbconvert-6.4.4[${PYTHON_USEDEP}]
>=dev-python/nbformat-5.3.0[${PYTHON_USEDEP}]
dev-python/overrides[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
dev-python/prometheus-client[${PYTHON_USEDEP}]
>=dev-python/pyzmq-24[${PYTHON_USEDEP}]
>=dev-python/send2trash-1.8.2[${PYTHON_USEDEP}]
>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
>=dev-python/tornado-6.2[${PYTHON_USEDEP}]
>=dev-python/traitlets-5.6.0[${PYTHON_USEDEP}]
dev-python/websocket-client[${PYTHON_USEDEP}]
"
BDEPEND="
dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
test? (
dev-python/ipykernel[${PYTHON_USEDEP}]
dev-python/flaky[${PYTHON_USEDEP}]
dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
dev-python/pytest-jupyter[${PYTHON_USEDEP}]
dev-python/pytest-timeout[${PYTHON_USEDEP}]
dev-python/pytest-tornasync[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=(
# This fails if your terminal is zsh (and maybe other non-bash as well?)
tests/test_terminal.py
# Fails because above is ignored
tests/auth/test_authorizer.py
# Fails with additional extensions installed
tests/extension/test_app.py::test_stop_extension
)
# FIXME: tests seem to be affected by previously installed version
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest \
-p pytest_tornasync.plugin \
-p jupyter_server.pytest_plugin \
-p pytest_console_scripts \
-p pytest_timeout
}
|
GitWeb
