blob: 8a22a6354a30358a99380771fefc49462a26a0fe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} pypy )
PYTHON_REQ_USE='tk?,threads(+)'
inherit distutils-r1 virtualx
MY_PN=Pillow
MY_P=${MY_PN}-${PV}
DESCRIPTION="Python Imaging Library (fork)"
HOMEPAGE="https://python-pillow.org/"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
LICENSE="HPND"
SLOT="0"
KEYWORDS="amd64 arm ~arm64 ppc ppc64 x86 ~amd64-linux ~x86-linux"
IUSE="doc examples imagequant jpeg jpeg2k lcms test tiff tk truetype webp zlib"
REQUIRED_USE="test? ( jpeg tiff )"
RDEPEND="
dev-python/olefile[${PYTHON_USEDEP}]
imagequant? ( media-gfx/libimagequant:0 )
jpeg? ( virtual/jpeg:0 )
jpeg2k? ( media-libs/openjpeg:2= )
lcms? ( media-libs/lcms:2= )
tiff? ( media-libs/tiff:0=[jpeg,zlib] )
truetype? ( media-libs/freetype:2= )
webp? ( media-libs/libwebp:0= )
zlib? ( sys-libs/zlib:0= )"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]
doc? (
dev-python/sphinx[${PYTHON_USEDEP}]
dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
)
test? (
<dev-python/pytest-3.10[${PYTHON_USEDEP}]
media-gfx/imagemagick[png]
)
"
S="${WORKDIR}/${MY_P}"
PATCHES=(
"${FILESDIR}/${PN}-5.2.0-fix-lib-paths.patch"
)
python_configure_all() {
# It's important that these flags are also passed during the install phase
# as well. Make sure of that if you change the lines below. See bug 661308.
mydistutilsargs=(
build_ext
--disable-platform-guessing
$(use_enable truetype freetype)
$(use_enable jpeg)
$(use_enable jpeg2k jpeg2000)
$(use_enable lcms)
$(use_enable tiff)
$(use_enable imagequant)
$(use_enable webp)
$(use_enable webp webpmux)
$(use_enable zlib)
)
}
python_compile() {
# Pillow monkeypatches distutils to achieve parallel compilation. This
# conflicts with distutils' builtin parallel computation (since py35)
# and make builds hang. To avoid that, we set MAX_CONCURRENCY=1 to
# disable monkeypatching. Can be removed when/if
# https://github.com/python-pillow/Pillow/pull/3272 is merged.
MAX_CONCURRENCY=1 distutils-r1_python_compile
}
python_compile_all() {
use doc && emake -C docs html
}
python_test() {
"${PYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
# no:relaxed: pytest-relaxed plugin make our tests fail. deactivate if installed
virtx pytest -vx Tests/test_*.py -p no:relaxed
}
python_install() {
python_doheader src/libImaging/*.h
distutils-r1_python_install
}
python_install_all() {
use doc && local HTML_DOCS=( docs/_build/html/. )
if use examples ; then
docinto example
dodoc docs/example/*
docompress -x /usr/share/doc/${PF}/example
fi
distutils-r1_python_install_all
}
|
GitWeb