blob: 4bb7ab84530d753f9ba8909393fd5e69b4d78e41 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit gnome2 python-r1
DESCRIPTION="Python client bindings for D-Bus AT-SPI"
HOMEPAGE="https://wiki.gnome.org/Accessibility"
# Note: only some of the tests are GPL-licensed, everything else is LGPL
LICENSE="LGPL-2 GPL-2+"
SLOT="0"
KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv sparc x86"
IUSE="test"
RESTRICT="!test? ( test )"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
DEPEND="
${PYTHON_DEPS}
>=dev-libs/atk-2.11.2
dev-python/dbus-python[${PYTHON_USEDEP}]
>=dev-python/pygobject-2.90.1:3[${PYTHON_USEDEP}]
"
RDEPEND="${DEPEND}
>=sys-apps/dbus-1
>=app-accessibility/at-spi2-core-2.34[introspection]
"
BDEPEND="virtual/pkgconfig
test? ( x11-libs/gtk+:3 )
"
src_prepare() {
gnome2_src_prepare
python_copy_sources
}
src_configure() {
python_foreach_impl run_in_build_dir gnome2_src_configure $(use_enable test tests)
}
src_compile() {
python_foreach_impl run_in_build_dir gnome2_src_compile
}
src_test() {
python_foreach_impl run_in_build_dir dbus-run-session emake check
}
src_install() {
installing() {
gnome2_src_install
python_optimize
}
python_foreach_impl run_in_build_dir installing
docinto examples
dodoc examples/*.py
}
|
GitWeb
