dev-python/requests-toolbelt/requests-toolbelt-0.9.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..11} pypy3 )

inherit distutils-r1

DESCRIPTION="A utility belt for advanced users of python-requests"
HOMEPAGE="
	https://toolbelt.readthedocs.io/
	https://github.com/requests/toolbelt/
	https://pypi.org/project/requests-toolbelt/
"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"

RDEPEND="
	<dev-python/requests-3.0.0[${PYTHON_USEDEP}]
"
BDEPEND="
	test? (
		dev-python/betamax[${PYTHON_USEDEP}]
		dev-python/mock[${PYTHON_USEDEP}]
	)
"

DOCS=( AUTHORS.rst HISTORY.rst README.rst )

PATCHES=(
	"${FILESDIR}/requests-toolbelt-0.8.0-test-tracebacks.patch"
	"${FILESDIR}/requests-toolbelt-0.9.1-tests.patch"
	"${FILESDIR}/requests-toolbelt-0.9.1-py310.patch"
)

distutils_enable_tests pytest

EPYTEST_DESELECT=(
	# Internet
	tests/test_multipart_encoder.py::TestFileFromURLWrapper::test_no_content_length_header
	tests/test_multipart_encoder.py::TestFileFromURLWrapper::test_read_file
	tests/test_multipart_encoder.py::TestMultipartEncoder::test_reads_file_from_url_wrapper
)

EPYTEST_IGNORE=(
	# certs have expired
	# (if you ever fix this, look into git history for proper
	# cryptography/pyopenssl logic)
	tests/test_x509_adapter.py
)