blob: 13f4d3a8a07b46ea443ffb3a2e22f935b3b6ab95 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1
DESCRIPTION="HTTP library for human beings"
HOMEPAGE="http://python-requests.org/ https://pypi.python.org/pypi/requests"
SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
IUSE="test"
RDEPEND="
app-misc/ca-certificates
>=dev-python/chardet-2.2.1[${PYTHON_USEDEP}]
dev-python/ndg-httpsclient[${PYTHON_USEDEP}]
>=dev-python/py-1.4.30[${PYTHON_USEDEP}]
dev-python/pyasn1[${PYTHON_USEDEP}]
>=dev-python/pyopenssl-0.13[$(python_gen_usedep 'python*' pypy)]
>=dev-python/urllib3-1.13.1-r1[${PYTHON_USEDEP}]
"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]
test? (
>=dev-python/pytest-2.8.1[${PYTHON_USEDEP}]
)
"
# >=dev-python/pytest-httpbin-0.0.7[${PYTHON_USEDEP}]
# tests connect to various remote sites
RESTRICT="test"
PATCHES=(
"${FILESDIR}"/${P}-system-packages.patch
"${FILESDIR}"/${PN}-2.5.0-system-cacerts.patch
)
python_prepare_all() {
# use system chardet & urllib3
rm -r requests/packages/{chardet,urllib3} || die
distutils-r1_python_prepare_all
}
python_test() {
py.test -v || die
}
|
GitWeb
