blob: 5de0c967feaa5574b3b63c190de91feb9d8e91a9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..11} pypy3 )
inherit distutils-r1
DESCRIPTION="Sphinx websupport extension"
HOMEPAGE="
https://www.sphinx-doc.org/
https://github.com/sphinx-doc/sphinxcontrib-websupport/
https://pypi.org/project/sphinxcontrib-websupport/
"
# pypi tarball is missing templates
SRC_URI="
https://github.com/sphinx-doc/sphinxcontrib-websupport/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-solaris"
RDEPEND="
>=dev-python/six-1.5[${PYTHON_USEDEP}]
dev-python/sphinxcontrib-serializinghtml[${PYTHON_USEDEP}]
"
# avoid circular dependency with sphinx
PDEPEND="
>=dev-python/sphinx-1.5.3[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
${PDEPEND}
>=dev-python/sqlalchemy-0.9[${PYTHON_USEDEP}]
>=dev-python/whoosh-2.0[${PYTHON_USEDEP}]
)"
distutils_enable_tests pytest
src_prepare() {
# breaks tests
sed -i -e '/pkg_resources/d' \
sphinxcontrib/websupport/__init__.py || die
# strip the .dev tag from version number
sed -i -e '/tag/d' setup.cfg || die
distutils-r1_src_prepare
}
python_compile() {
distutils-r1_python_compile
find "${BUILD_DIR}" -name '*.pth' -delete || die
}
python_test() {
distutils_write_namespace sphinxcontrib
cd "${T}" || die
epytest "${S}"/tests
}
|
GitWeb
