blob: 7d4b032dd291a503287acba684d5546310a35c9f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{9..10} )
inherit distutils-r1
DESCRIPTION="Meta-language for DSL implementation inspired by Xtext"
HOMEPAGE="
https://pypi.org/project/textX/
https://github.com/textX/textX/
"
SRC_URI="
https://github.com/textX/textX/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
>=dev-python/Arpeggio-2.0.0[${PYTHON_USEDEP}]
dev-python/future[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/click[${PYTHON_USEDEP}]
dev-python/html5lib[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_test() {
cp -a "${BUILD_DIR}"/{install,test} || die
local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
# Update the shebang
sed -e "s:install/usr/bin/${EPYTHON}:test/usr/bin/${EPYTHON}:" \
-i "${BUILD_DIR}"/test/usr/bin/textx || die
# Install necessary plugins
local plugins=(
tests/functional/subcommands/example_project
tests/functional/registration/projects/*
)
local p
for p in "${plugins[@]}"; do
pushd "${p}" >/dev/null || die
distutils_pep517_install "${BUILD_DIR}"/test
popd >/dev/null || die
done
epytest tests/functional
}
|
GitWeb
