blob: 1d25771a50768f6b99e839b9141f07bf7ee40a75 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
USE_RUBY="ruby27 ruby30 ruby31"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md ROADMAP.md SECURITY.md"
RUBY_FAKEGEM_GEMSPEC="nokogiri.gemspec"
RUBY_FAKEGEM_EXTENSIONS=(ext/nokogiri/extconf.rb)
inherit ruby-fakegem multilib
DESCRIPTION="Nokogiri is an HTML, XML, SAX, and Reader parser"
HOMEPAGE="https://www.nokogiri.org/"
LICENSE="MIT"
SRC_URI="https://github.com/sparklemotion/nokogiri/archive/v${PV}.tar.gz -> ${P}-git.tgz"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~s390 sparc x86"
SLOT="0"
IUSE=""
RDEPEND="${RDEPEND}
>=dev-libs/libxml2-2.10.3:=
>=dev-libs/libxslt-1.1.37
sys-libs/zlib
virtual/libiconv"
DEPEND="${DEPEND}
>=dev-libs/libxml2-2.10.3
>=dev-libs/libxslt-1.1.37
>=sys-libs/zlib-1.2.13
virtual/libiconv"
ruby_add_rdepend ">=dev-ruby/racc-1.4:0"
ruby_add_bdepend "
dev-ruby/mini_portile2:2.8
>=dev-ruby/rexical-1.0.7
dev-ruby/rdoc
test? ( dev-ruby/minitest )"
all_ruby_prepare() {
sed -i \
-e '/tasks\/cross_compile/s:^:#:' \
-e '/:test.*prerequisites/s:^:#:' \
-e '/license/ s:^:#:' \
Rakefile || die
# Remove the cross compilation options since they interfere with
# native building.
sed -i -e 's/cross_compile = true/cross_compile = false/' Rakefile || die
sed -i -e '/cross_config_options/d' Rakefile || die
sed -e '/simplecov/,/^end/ s:^:#:' \
-e '/reporters/I s:^:#:' \
-i test/helper.rb || die
# There is no need for mini_portile2 to be a runtime dependency on Gentoo
sed -i -e '/mini_portile2/ s:^:#:' ${RUBY_FAKEGEM_GEMSPEC} || die
}
each_ruby_configure() {
NOKOGIRI_USE_SYSTEM_LIBRARIES=true \
${RUBY} -Cext/${PN} extconf.rb \
--with-zlib-include="${EPREFIX}"/usr/include \
--with-zlib-lib="${EPREFIX}"/$(get_libdir) \
--with-iconv-include="${EPREFIX}"/usr/include \
--with-iconv-lib="${EPREFIX}"/$(get_libdir) \
--with-xml2-include="${EPREFIX}"/usr/include/libxml2 \
--with-xml2-lib="${EPREFIX}"/usr/$(get_libdir) \
--with-xslt-dir="${EPREFIX}"/usr \
--with-iconvlib=iconv \
|| die "extconf.rb failed"
}
each_ruby_compile() {
if ! [[ -f lib/nokogiri/css/tokenizer.rb ]]; then
${RUBY} -S rake lib/nokogiri/css/tokenizer.rb || die "rexical failed"
fi
if ! [[ -f lib/nokogiri/css/parser.rb ]]; then
${RUBY} -S rake lib/nokogiri/css/parser.rb || die "racc failed"
fi
emake -Cext/${PN} \
V=1 \
CFLAGS="${CFLAGS} -fPIC" \
archflag="${LDFLAGS}" || die "make extension failed"
cp -l ext/${PN}/${PN}$(get_modname) lib/${PN}/ || die
}
each_ruby_test() {
${RUBY} -Ilib:.:test -e 'Dir["test/**/test_*.rb"].each {|f| require f}' || die
}
|
GitWeb