1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit desktop wrapper
DESCRIPTION="A complete toolset for C and C++ development"
HOMEPAGE="https://www.jetbrains.com/clion"
SRC_URI="https://download.jetbrains.com/cpp/CLion-${PV}.tar.gz"
LICENSE="|| ( IDEA IDEA_Academic IDEA_Classroom IDEA_OpenSource IDEA_Personal )
Apache-1.1 Apache-2.0 BSD BSD-2 CC0-1.0 CDDL-1.1 CPL-0.5 CPL-1.0
EPL-1.0 EPL-2.0 GPL-2 GPL-2-with-classpath-exception GPL-3 ISC JDOM
LGPL-2.1+ LGPL-3 MIT MPL-1.0 MPL-1.1 OFL public-domain PSF-2 UoI-NCSA ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RESTRICT="bindist mirror splitdebug"
BDEPEND="dev-util/patchelf"
# RDEPENDS may cause false positives in repoman.
# clion requires cmake and gdb at runtime to build and debug C/C++ projects
RDEPEND="
|| (
>=app-accessibility/at-spi2-core-2.46.0:2
( app-accessibility/at-spi2-atk dev-libs/atk )
)
dev-libs/expat
dev-libs/glib:2
dev-libs/nspr
dev-libs/nss
dev-util/cmake
dev-util/ninja
media-libs/alsa-lib
media-libs/freetype:2
media-libs/mesa
net-print/cups
sys-apps/dbus
sys-devel/gdb
x11-libs/cairo
x11-libs/pango
sys-libs/zlib
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXcursor
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXi
x11-libs/libXrandr
x11-libs/libXrender
x11-libs/libXtst
x11-libs/libXxf86vm
x11-libs/libdrm
x11-libs/libxcb
x11-libs/libxkbcommon"
QA_PREBUILT="opt/${P}/*"
src_prepare() {
default
local remove_me=(
bin/cmake
bin/lldb/linux
bin/gdb/linux
bin/ninja
license/CMake*
lib/pty4j-native/linux/aarch64
lib/pty4j-native/linux/arm
lib/pty4j-native/linux/mips64el
lib/pty4j-native/linux/ppc64le
plugins/remote-dev-server/selfcontained
plugins/cwm-plugin/quiche-native/linux-aarch64
)
use amd64 || remove_me+=( lib/pty4j-native/linux/x86_64 )
use x86 || remove_me+=( lib/pty4j-native/linux/x86 )
rm -rv "${remove_me[@]}" || die
for file in "jbr/lib/"/{libjcef.so,jcef_helper}
do
if [[ -f "${file}" ]]; then
patchelf --set-rpath '$ORIGIN' ${file} || die
fi
done
}
src_install() {
local dir="/opt/${P}"
insinto "${dir}"
doins -r *
fperms 755 "${dir}"/bin/{clion.sh,fsnotifier,inspect.sh,ltedit.sh,repair,clang/linux/{clangd,clang-tidy,clazy-standalone,llvm-symbolizer}}
if [[ -d jbr ]]; then
fperms 755 "${dir}"/jbr/bin/{java,javac,jdb,jrunscript,keytool,rmiregistry,serialver}
# Fix #763582
fperms 755 "${dir}"/jbr/lib/{chrome-sandbox,jcef_helper,jexec,jspawnhelper}
fi
dosym -r "${EPREFIX}/usr/bin/ninja" "${dir}"/bin/ninja/linux/ninja
make_wrapper "${PN}" "${dir}/bin/${PN}.sh"
newicon "bin/${PN}.svg" "${PN}.svg"
make_desktop_entry "${PN}" "CLion" "${PN}" "Development;IDE;"
# recommended by: https://confluence.jetbrains.com/display/IDEADEV/Inotify+Watches+Limit
dodir /usr/lib/sysctl.d/
echo "fs.inotify.max_user_watches = 524288" > "${D}/usr/lib/sysctl.d/30-clion-inotify-watches.conf" || die
}
|
GitWeb