games-util/eureka/eureka-1.27b.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit desktop toolchain-funcs xdg

DESCRIPTION="Graphical map editor for games using the DOOM engine"
HOMEPAGE="http://eureka-editor.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}-editor/Eureka/${PV%[a-z]}/${P}-source.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+opengl"

DEPEND="
	sys-libs/zlib
	x11-libs/fltk:1[opengl?]
	opengl? (
		media-libs/glu
		virtual/opengl
	)
"

RDEPEND="
	${DEPEND}
"

S="${WORKDIR}/${P}-source"

PATCHES=(
	"${FILESDIR}"/${PN}-Makefile.patch
)

DOCS=(
	AUTHORS.txt
	CHANGES.txt
	README.txt
	TODO.txt
)

src_compile() {
	emake \
		CXX="$(tc-getCXX)" \
		OPENGL="$(usex opengl 1 0)"
}

src_install() {
	emake install PREFIX="${ED}/usr"
	einstalldocs

	doicon -s 32 misc/${PN}.xpm
	domenu misc/${PN}.desktop
}