blob: f0c387f938cd298ac8fd237da0591774face4e17 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools eutils gnome2-utils virtualx xdg
DESCRIPTION="Cinnamon's settings daemon"
HOMEPAGE="https://projects.linuxmint.com/cinnamon/"
SRC_URI="https://github.com/linuxmint/cinnamon-settings-daemon/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+colord cups input_devices_wacom smartcard systemd"
RESTRICT="test"
# udev is non-optional since lots of plugins, not just gudev, pull it in
RDEPEND="
>=dev-libs/glib-2.38:2
dev-libs/libgudev:=
>=gnome-base/libgnomekbd-3.6
>=gnome-extra/cinnamon-desktop-4.6:0=
media-libs/fontconfig
>=media-libs/lcms-2.2:2
media-libs/libcanberra:0=[gtk3]
>=sys-apps/dbus-1.1.2
>=sys-auth/polkit-0.97
x11-libs/gdk-pixbuf:2
>=x11-libs/gtk+-3.9.10:3
>=x11-libs/libnotify-0.7.3:0=
x11-libs/libX11
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXi
>=x11-libs/libxklavier-5.0
>=sys-power/upower-0.9.11
colord? ( >=x11-misc/colord-0.1.27:= )
cups? (
>=net-print/cups-1.4[dbus]
app-admin/system-config-printer
net-print/cups-pk-helper )
input_devices_wacom? (
>=dev-libs/libwacom-0.7
>=gnome-base/librsvg-2.36.2
x11-drivers/xf86-input-wacom
x11-libs/libXtst )
smartcard? ( >=dev-libs/nss-3.11.2 )
systemd? ( sys-apps/systemd:0= )
!systemd? ( sys-auth/elogind:0= )
"
DEPEND="${RDEPEND}
dev-libs/libxml2:2
x11-base/xorg-proto
"
BDEPEND="
dev-util/gdbus-codegen
>=dev-util/intltool-0.37.1
virtual/pkgconfig
"
PATCHES=(
# Make account-services optional
"${FILESDIR}"/${PN}-3.8.0-accountservice.patch
)
src_prepare() {
xdg_src_prepare
eautoreconf
gnome2_disable_deprecation_warning
# Disable broken test
sed -e '/g_test_add_func ("\/color\/edid/d' \
-i plugins/color/gcm-self-test.c || die
}
src_configure() {
# no point in disabling gudev since other plugins pull it in
econf \
--disable-maintainer-mode \
--disable-schemas-compile \
--enable-compile-warnings=minimum \
--disable-static \
--enable-gudev \
--enable-polkit \
--enable-logind \
--disable-accountservice \
$(use_enable colord color) \
$(use_enable cups) \
$(use_enable smartcard smartcard-support) \
$(use_enable input_devices_wacom wacom)
}
src_test() {
virtx emake check
}
src_install() {
default
find "${D}" -name '*.la' -delete || die
dodoc MAINTAINERS
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
GitWeb