blob: 18e4f981059d3cd79b26269b05386921dacea914 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 2022-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit gnome.org meson python-any-r1 vala virtualx
DESCRIPTION="Building blocks for modern GNOME applications"
HOMEPAGE="https://gnome.pages.gitlab.gnome.org/libadwaita/ https://gitlab.gnome.org/GNOME/libadwaita"
LICENSE="LGPL-2.1+"
SLOT="1"
IUSE="+introspection test +vala"
REQUIRED_USE="vala? ( introspection )"
KEYWORDS="amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
RDEPEND="
>=dev-libs/glib-2.76:2
>=gui-libs/gtk-4.11.3:4[introspection?]
dev-libs/appstream:=
dev-libs/fribidi
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
"
DEPEND="${RDEPEND}
x11-base/xorg-proto"
BDEPEND="
${PYTHON_DEPS}
vala? ( $(vala_depend) )
dev-util/glib-utils
sys-devel/gettext
virtual/pkgconfig
"
src_prepare() {
default
use vala && vala_setup
}
src_configure() {
local emesonargs=(
# Never use gi-docgen subproject
--wrap-mode nofallback
-Dprofiling=false
$(meson_feature introspection)
$(meson_use vala vapi)
-Dgtk_doc=false # we ship pregenerated docs
$(meson_use test tests)
-Dexamples=false
)
meson_src_configure
}
src_test() {
virtx meson_src_test --timeout-multiplier 2
}
src_install() {
meson_src_install
insinto /usr/share/gtk-doc/html
# This will install libadwaita API docs unconditionally, but this is intentional
doins -r "${S}"/doc/libadwaita-1
}
|
GitWeb
