blob: 3b5100b4a1976d3d7bac99e3ec4449d4c2c82c2c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
QTMIN=5.15.2
VIRTUALX_REQUIRED="test"
inherit ecm kde.org optfeature
DESCRIPTION="Provider for platform independent hardware discovery, abstraction and management"
LICENSE="LGPL-2.1+"
KEYWORDS="amd64 ~arm ~arm64 ~ppc64 x86"
IUSE="ios nls"
BDEPEND="
sys-devel/bison
sys-devel/flex
nls? ( >=dev-qt/linguist-tools-${QTMIN}:5 )
"
RDEPEND="
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtdeclarative-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
sys-fs/udisks:2
virtual/libudev:=
ios? (
app-pda/libimobiledevice:=
app-pda/libplist:=
)
"
DEPEND="${RDEPEND}
test? ( >=dev-qt/qtconcurrent-${QTMIN}:5 )
"
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package ios IMobileDevice)
$(cmake_use_find_package ios PList)
)
ecm_src_configure
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "Media player devices support" app-misc/media-player-info
fi
ecm_pkg_postinst
}
|
GitWeb
