blob: 5eaeb57c3e4795179e7a6cfbe5bccb046a0e2438 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 )
inherit eutils multilib python-single-r1 toolchain-funcs
DESCRIPTION="A fast, modern and generic image processing library"
HOMEPAGE="http://www.exactcode.de/site/open_source/exactimage/"
SRC_URI="http://dl.exactcode.de/oss/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="expat jpeg lua openexr php perl png python ruby swig tiff truetype X"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="x11-libs/agg[truetype]
sys-libs/zlib
expat? ( dev-libs/expat )
jpeg? ( virtual/jpeg )
lua? ( dev-lang/lua )
openexr? ( media-libs/openexr )
php? ( dev-lang/php )
perl? ( dev-lang/perl )
png? ( >=media-libs/libpng-1.2.43 )
python? ( ${PYTHON_DEPS} )
ruby? ( dev-lang/ruby )
tiff? ( media-libs/tiff )
truetype? ( >=media-libs/freetype-2 )
X? (
x11-libs/libXext
x11-libs/libXt
x11-libs/libICE
x11-libs/libSM
)"
DEPEND="${RDEPEND}
virtual/pkgconfig
swig? ( dev-lang/swig )"
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
eapply \
"${FILESDIR}"/${PN}-0.7.5-libpng14.patch \
"${FILESDIR}"/${P}-libpng15.patch \
"${FILESDIR}"/${P}-gcc6.patch
eapply_user
# fix python hardcoded path wrt bug #327171
sed -i -e "s:python2.5:${EPYTHON}:" \
-e "s:\$(libdir):usr/$(get_libdir):" \
"${S}"/api/python/Makefile || die
# Respect user CFLAGS/CXXFLAGS.
sed -i \
-e '/C\(XX\)\?FLAGS =/s/-O2//' \
-e "\$aCFLAGS += ${CFLAGS}\nCXXFLAGS += ${CXXFLAGS}" \
Makefile || die
# Show commands. Use qualified CC/CXX.
sed -i \
-e '/^Q =/d' \
-e '/^\t@echo /d' \
-e "\$aCC:=$(tc-getCC)\nCXX:=$(tc-getCXX)" \
build/bottom.make || die
# The copied string fits exactly. Use memcpy to reflect that a null
# terminator is not needed.
sed -i \
-e 's/strcpy(\([^,]*\)\(,["a-zA-Z -]*\))/memcpy(\1\2, sizeof(\1))/' \
codecs/tga.cc || die
}
src_configure() {
# evas -> enlightenment overlay
# bardecode -> protected by custom license
# libungif -> not supported anymore
./configure \
--prefix=/usr \
--libdir=/usr/$(get_libdir) \
$(use_with X x11) \
$(use_with truetype freetype) \
--without-evas \
$(use_with jpeg libjpeg) \
$(use_with tiff libtiff) \
$(use_with png libpng) \
--without-libungif \
--without-jasper \
$(use_with openexr) \
$(use_with expat) \
--without-lcms \
--without-bardecode \
$(use_with lua) \
$(use_with swig) \
$(use_with perl) \
$(use_with python) \
$(use_with php) \
$(use_with ruby) || die
}
|
GitWeb