blob: 0704851b93fc8268feefc750716292a6fd5d99d0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
if [[ "${PV#9999}" != "${PV}" ]] ; then
inherit git-r3
EGIT_REPO_URI="https://git.videolan.org/git/libbluray.git"
else
KEYWORDS="amd64 ~arm ~arm64 ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd"
SRC_URI="https://downloads.videolan.org/pub/videolan/libbluray/${PV}/${P}.tar.bz2"
fi
inherit autotools java-pkg-opt-2 flag-o-matic multilib-minimal
DESCRIPTION="Blu-ray playback libraries"
HOMEPAGE="https://www.videolan.org/developers/libbluray.html"
LICENSE="LGPL-2.1"
SLOT="0/2"
IUSE="aacs bdplus +fontconfig java static-libs +truetype utils +xml"
COMMON_DEPEND="
xml? ( >=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}] )
fontconfig? ( >=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}] )
truetype? ( >=media-libs/freetype-2.5.0.1:2[${MULTILIB_USEDEP}] )
"
RDEPEND="
${COMMON_DEPEND}
aacs? ( >=media-libs/libaacs-0.6.0[${MULTILIB_USEDEP}] )
bdplus? ( media-libs/libbdplus[${MULTILIB_USEDEP}] )
java? ( >=virtual/jre-1.6 )
"
DEPEND="
${COMMON_DEPEND}
java? (
>=virtual/jdk-1.6
dev-java/ant-core
)
virtual/pkgconfig
"
DOCS=( ChangeLog README.txt )
src_prepare() {
default
unset JDK_HOME #621992
if use java ; then
export JDK_HOME="$(java-config -g JAVA_HOME)"
# don't install a duplicate jar file
sed -i '/^jar_DATA/d' Makefile.am || die
java-pkg-opt-2_src_prepare
fi
eautoreconf
}
multilib_src_configure() {
ECONF_SOURCE="${S}" econf \
--disable-optimizations \
$(multilib_native_use_enable utils examples) \
$(multilib_native_use_enable java bdjava-jar) \
$(use_with fontconfig) \
$(use_with truetype freetype) \
$(use_enable static-libs static) \
$(use_with xml libxml2)
}
multilib_src_install() {
emake DESTDIR="${D}" install
if multilib_is_native_abi && use utils; then
cd .libs/ || die
dobin index_dump mobj_dump mpls_dump bd_info bdsplice clpi_dump hdmv_test libbluray_test list_titles sound_dump
if use java; then
dobin bdj_test
fi
fi
if multilib_is_native_abi && use java; then
java-pkg_dojar "${BUILD_DIR}"/.libs/${PN}-j2se-*.jar
fi
}
multilib_src_install_all() {
einstalldocs
find "${D}" -name '*.la' -delete || die
}
|
GitWeb