blob: bbf5a2b99f95fecafbbb41798e90799b243ba33b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
PYTHON_REQ_USE='threads(+)'
inherit meson-multilib python-single-r1
DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
HOMEPAGE="https://drobilla.net/software/lilv.html"
SRC_URI="https://download.drobilla.net/${P}.tar.xz"
LICENSE="ISC"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~sparc x86"
IUSE="doc python test tools"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RESTRICT="!test? ( test )"
BDEPEND="
virtual/pkgconfig
doc? (
app-doc/doxygen
dev-python/sphinx
dev-python/sphinx-lv2-theme
)
"
# Take care on bumps to check minimum versions!
RDEPEND="
${PYTHON_DEPS}
>=dev-libs/serd-0.30.10[${MULTILIB_USEDEP}]
>=dev-libs/sord-0.16.10[${MULTILIB_USEDEP}]
media-libs/libsndfile
>=media-libs/lv2-1.18.2[${MULTILIB_USEDEP}]
>=media-libs/sratom-0.6.10[${MULTILIB_USEDEP}]
"
DEPEND="${RDEPEND}"
pkg_setup() {
python_setup
}
src_prepare() {
default
# fix doc installation path
sed -iE "s%install_dir: docdir / 'lilv-0',%install_dir: docdir / '${PF}',%g" doc/c/meson.build || die
}
multilib_src_configure() {
local emesonargs=(
$(meson_native_use_feature doc docs)
$(meson_feature python bindings_py)
$(meson_feature test tests)
$(meson_feature tools)
)
meson_src_configure
}
multilib_src_install() {
meson_src_install
python_optimize
}
multilib_src_install_all() {
local DOCS=( AUTHORS NEWS README.md )
einstalldocs
newenvd - 60lv2 <<-EOF
LV2_PATH=${EPREFIX}/usr/$(get_libdir)/lv2
EOF
}
|
GitWeb
