blob: 576d7a257f62a851358723c5d79cfcec5050602d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Copyright 2021-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..11} )
inherit cmake python-single-r1
DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
HOMEPAGE="https://libtorrent.org/ https://github.com/arvidn/libtorrent"
SRC_URI="https://github.com/arvidn/libtorrent/releases/download/v${PV}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0/2.0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="+dht debug gnutls python ssl test"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RESTRICT="!test? ( test )"
DEPEND="
dev-libs/boost:=
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-libs/boost[python,${PYTHON_USEDEP}]
')
)
ssl? (
gnutls? ( net-libs/gnutls:= )
!gnutls? ( dev-libs/openssl:= )
)
"
RDEPEND="${DEPEND}"
BDEPEND="python? (
$(python_gen_cond_dep '
dev-python/setuptools[${PYTHON_USEDEP}]
')
)"
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_configure() {
local mycmakeargs=(
-DCMAKE_CXX_STANDARD=17
-DBUILD_SHARED_LIBS=ON
-Dbuild_examples=OFF
-Ddht=$(usex dht ON OFF)
-Dencryption=$(usex ssl ON OFF)
-Dgnutls=$(usex gnutls ON OFF)
-Dlogging=$(usex debug ON OFF)
-Dpython-bindings=$(usex python ON OFF)
-Dbuild_tests=$(usex test ON OFF)
)
# We need to drop the . from the Python version to satisfy Boost's
# FindBoost.cmake module, bug #793038.
use python && mycmakeargs+=( -Dboost-python-module-name="${EPYTHON/./}" )
cmake_src_configure
}
src_test() {
local myctestargs=(
# Needs running UPnP server
-E "test_upnp"
)
# Checked out Fedora's test workarounds for inspiration
# https://src.fedoraproject.org/rpms/rb_libtorrent/blob/rawhide/f/rb_libtorrent.spec#_120
# -j1 for https://bugs.gentoo.org/854603#c1
LD_LIBRARY_PATH="${BUILD_DIR}:${LD_LIBRARY_PATH}" cmake_src_test -j1
}
|
GitWeb
