blob: dc2cbff5d20d5aaeef363d4ca50a5443a7e21fa9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit qmail webapp autotools
MY_P=${P/_rc/-rc}
DESCRIPTION="A web interface for managing a qmail system with virtual domains"
HOMEPAGE="http://www.inter7.com/qmailadmin.html"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
WEBAPP_MANUAL_SLOT="yes"
KEYWORDS="amd64 arm ~hppa ~ia64 ppc s390 sparc x86"
IUSE="maildrop"
# the RESTRICT is because the vpopmail lib directory is locked down
# and non-root can't access them.
RESTRICT="userpriv"
RDEPEND="virtual/qmail
>=net-mail/vpopmail-5.4.33
net-mail/autorespond
maildrop? ( >=mail-filter/maildrop-2.0.1 )"
DEPEND=${RDEPEND}
S="${WORKDIR}"/${MY_P}
src_prepare() {
eapply "${FILESDIR}"/${PN}-1.2.9-maildir.patch
eapply "${FILESDIR}"/${PN}-1.2.12-quota-overflow.patch
eapply "${FILESDIR}"/${PN}-1.2.15-quota-security.patch
eapply_user
eautoreconf
}
src_configure() {
# Pass spam stuff through $@ so we get the quoting right
if use maildrop ; then
set -- --enable-modify-spam \
--enable-spam-command='|preline maildrop /etc/maildroprc'
else
set --
fi
econf \
--enable-valias \
--enable-vpopmaildir=/var/vpopmail \
--enable-htmldir="${MY_HTDOCSDIR}" \
--enable-imagedir="${MY_HTDOCSDIR}"/images \
--enable-imageurl=/${PN}/images \
--enable-htmllibdir=/usr/share/${PN}/htmllib \
--enable-cgibindir="${MY_CGIBINDIR}" \
--enable-cgipath=/cgi-bin/${PN} \
--enable-qmaildir="${QMAIL_HOME}" \
--enable-autoresponder-path="${QMAIL_HOME}"/bin \
--enable-true-path=/bin \
--enable-ezmlmdir=/usr/bin \
--enable-domain-autofill \
--enable-modify-quota \
--enable-no-cache \
--enable-trivial-password \
--enable-catchall \
--enable-maxusersperpage=50 \
--enable-maxaliasesperpage=50 \
--enable-vpopuser=vpopmail \
--enable-vpopgroup=vpopmail \
"$@"
}
src_install() {
webapp_src_preinst
local DOCS=(
AUTHORS INSTALL README.hooks BUGS TODO ChangeLog TRANSLATORS
NEWS FAQ README contrib/*
)
default
webapp_src_install
}
pkg_postinst() {
einfo "If you would like support for ezmlm mailing lists inside qmailadmin,"
einfo "please emerge some variant of ezmlm-idx."
webapp_pkg_postinst
}
|
GitWeb