blob: 3d701ad41fa90a8c8452cc2a5b30e35b35a786c1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=(python3_{7..10})
DISTUTILS_USE_SETUPTOOLS=rdepend
inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
DESCRIPTION="Download videos from YouTube.com (and more sites...)"
HOMEPAGE="https://youtube-dl.org/ https://github.com/ytdl-org/youtube-dl/"
SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
S=${WORKDIR}/${PN}
LICENSE="public-domain"
KEYWORDS="amd64 arm ~arm64 ~hppa ppc ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
SLOT="0"
RDEPEND="
dev-python/pycryptodome[${PYTHON_USEDEP}]
"
distutils_enable_tests nose
src_prepare() {
sed -i -e '/flake8/d' Makefile || die
distutils-r1_src_prepare
}
python_test() {
emake offlinetest
}
python_install_all() {
doman youtube-dl.1
newbashcomp youtube-dl.bash-completion youtube-dl
insinto /usr/share/zsh/site-functions
newins youtube-dl.zsh _youtube-dl
insinto /usr/share/fish/vendor_completions.d
doins youtube-dl.fish
distutils-r1_python_install_all
rm -r "${ED}"/usr/etc || die
rm -r "${ED}"/usr/share/doc/youtube_dl || die
}
pkg_postinst() {
elog "youtube-dl(1) / https://bugs.gentoo.org/355661 /"
elog "https://github.com/rg3/youtube-dl/blob/master/README.md#faq :"
elog
elog "youtube-dl works fine on its own on most sites. However, if you want"
elog "to convert video/audio, you'll need ffmpeg (media-video/ffmpeg)."
elog "On some sites - most notably YouTube - videos can be retrieved in"
elog "a higher quality format without sound. youtube-dl will detect whether"
elog "ffmpeg is present and automatically pick the best option."
elog
elog "Videos or video formats streamed via RTMP protocol can only be"
elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
elog
elog "Downloading MMS and RTSP videos requires either mplayer"
elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
elog
elog "If you want youtube-dl to embed thumbnails from the metadata into the"
elog "resulting MP4 files, consider installing media-video/atomicparsley"
}
|
GitWeb
