blob: 788cb937f34c7ee4c1092baee29ad2531ed974b1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="5"
inherit eutils systemd
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="git://linux-nfs.org/~steved/rpcbind.git"
inherit autotools git-r3
else
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
fi
DESCRIPTION="portmap replacement which supports RPC over various protocols"
HOMEPAGE="https://sourceforge.net/projects/rpcbind/"
LICENSE="BSD"
SLOT="0"
IUSE="debug selinux systemd tcpd warmstarts"
CDEPEND=">=net-libs/libtirpc-0.2.3:=
systemd? ( sys-apps/systemd:= )
tcpd? ( sys-apps/tcp-wrappers )"
DEPEND="${CDEPEND}
virtual/pkgconfig"
RDEPEND="${CDEPEND}
selinux? ( sec-policy/selinux-rpcbind )"
src_prepare() {
[[ ${PV} == "9999" ]] && eautoreconf
epatch_user
}
src_configure() {
econf \
--with-statedir="${EPREFIX}"/run/${PN} \
--with-systemdsystemunitdir=$(usex systemd "$(systemd_get_unitdir)" "no") \
$(use_enable tcpd libwrap) \
$(use_enable debug) \
$(use_enable warmstarts)
}
src_install() {
default
newinitd "${FILESDIR}"/${PN}.initd ${PN}
newconfd "${FILESDIR}"/${PN}.confd ${PN}
systemd_dounit "${FILESDIR}"/${PN}.service
}
|
GitWeb
