blob: 9dcccc8acdbd3f0a78230b434b310463795c8d5a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
QTMIN="5.9.0"
inherit flag-o-matic optfeature qmake-utils xdg
DESCRIPTION="Simple (yet powerful) feed reader"
HOMEPAGE="https://github.com/martinrotter/rssguard"
SRC_URI="https://github.com/martinrotter/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="|| ( LGPL-3 GPL-2+ ) AGPL-3+ BSD GPL-3+ MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="debug webengine"
BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
DEPEND="
>=dev-qt/qtcore-${QTMIN}:5
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtdeclarative-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtmultimedia-${QTMIN}:5[gstreamer]
>=dev-qt/qtnetwork-${QTMIN}:5[ssl]
>=dev-qt/qtsql-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5[widgets(+)] )
"
RDEPEND="${DEPEND}"
DOCS=( README.md resources/docs/Documentation.md )
src_prepare() {
default
sed -e 's:$$PREFIX/lib:$$PREFIX/'$(get_libdir)':' -i pri/install.pri || die
}
src_configure() {
eqmake5_args=(
CONFIG+=$(usex debug debug release)
USE_WEBENGINE=$(usex webengine true false)
PREFIX="${EPREFIX}"/usr
INSTALL_ROOT=.
)
# https://github.com/martinrotter/rssguard/issues/156
is-flagq "-flto*" && eqmake5_args+=( CONFIG+=ltcg )
eqmake5 "${eqmake5_args[@]}"
}
src_install() {
emake -j1 install INSTALL_ROOT="${D}"
einstalldocs
}
pkg_postinst() {
xdg_pkg_postinst
if use webengine; then
optfeature "ad blocking functionality" net-libs/nodejs[npm]
elog "Adblocker module requires additional npm modules to be installed:"
elog "npm i -g @cliqz/adblocker tldts-experimental"
fi
}
|
GitWeb
