blob: 76af45cb877b80486ce4a1f23c5af11a1850de52 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( pypy3 python3_{8..11} )
inherit cmake python-any-r1 systemd
DESCRIPTION="Cross-platform Direct Connect client"
HOMEPAGE="https://airdcpp-web.github.io/"
SRC_URI="https://github.com/airdcpp-web/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="amd64 ~riscv x86"
LICENSE="GPL-2+"
SLOT="0"
IUSE="debug nat-pmp +tbb +webui"
RDEPEND="
acct-user/airdcppd
acct-group/airdcppd
app-arch/bzip2
dev-cpp/websocketpp
dev-libs/boost:=
dev-libs/leveldb:=
dev-libs/libmaxminddb:=
dev-libs/openssl:0=[-bindist(-)]
net-libs/miniupnpc:=
sys-libs/zlib
virtual/libiconv
nat-pmp? ( net-libs/libnatpmp:= )
tbb? ( dev-cpp/tbb:= )
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
${PYTHON_DEPS}
"
PDEPEND="webui? ( www-apps/airdcpp-webui )"
PATCHES=(
"${FILESDIR}/${P}-fix-odr.patch"
)
src_configure() {
local mycmakeargs=(
-DENABLE_NATPMP=$(usex nat-pmp)
-DENABLE_TBB=$(usex tbb)
-DINSTALL_WEB_UI=OFF
)
CMAKE_BUILD_TYPE=$(usex debug Debug Gentoo) cmake_src_configure
}
src_install() {
cmake_src_install
newconfd "${FILESDIR}/airdcppd.confd" airdcppd
newinitd "${FILESDIR}/airdcppd.initd" airdcppd
systemd_dounit "${FILESDIR}/airdcppd.service"
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
elog "Run 'airdcppd --configure' to set up ports and authentication"
fi
}
|
GitWeb
