blob: d100dad51cbcd80794495608916bfc2ba7dcf82f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
WX_GTK_VER=3.0
inherit autotools desktop toolchain-funcs wxwidgets
DESCRIPTION="Chemical 3D graphics program with GAMESS input builder"
HOMEPAGE="http://www.scl.ameslab.gov/MacMolPlt/"
SRC_URI="https://wxmacmolplt.googlecode.com/files/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
media-libs/glew:0=
media-libs/mesa[X(+)]
x11-libs/wxGTK:${WX_GTK_VER}[X,opengl]"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=( "${FILESDIR}"/${P}-glew.patch )
src_prepare() {
default
sed \
-e "/^dist_doc_DATA/d" \
-i Makefile.am || die "Failed to disable installation of LICENSE file"
eautoreconf
}
src_configure() {
tc-export PKG_CONFIG
setup-wxwidgets unicode
econf \
--with-glew \
--without-ming
}
src_install() {
default
doicon resources/${PN}.png
make_desktop_entry ${PN} wxMacMolPlt ${PN} "Science;DataVisualization;"
}
|
GitWeb
