blob: 18e7b9c1f4b1844d3219566677408f14f15a2b86 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
MY_PN=Osi
DESCRIPTION="COIN-OR Open Solver Interface"
HOMEPAGE="https://github.com/coin-or/Osi/"
SRC_URI="https://github.com/coin-or/${MY_PN}/archive/releases/${PV}.tar.gz
-> ${P}.tar.gz"
LICENSE="EPL-1.0"
# major soname component
SLOT="0/1"
KEYWORDS="~amd64 ~loong ~riscv ~x86 ~amd64-linux ~x86-linux"
# No USE=glpk because upstream only supports an ancient version of it. The
# following issues were all closed by... documenting that it doesn't work:
#
# * https://github.com/coin-or/Osi/issues/71
# * https://github.com/coin-or/Osi/issues/107
# * https://github.com/coin-or/Osi/issues/118
#
IUSE="doc examples static-libs test"
RESTRICT="!test? ( test )"
# Fortran is NOT needed, but the ./configure scripts for all of the CoinOR
# packages contain a check for it. Gentoo bug 601648 and upstream issue,
#
# https://github.com/coin-or/CoinUtils/issues/132
#
BDEPEND="virtual/fortran
virtual/pkgconfig
doc? ( app-text/doxygen[dot] )
test? ( sci-libs/coinor-sample )"
DEPEND="sci-libs/coinor-utils:="
RDEPEND="${DEPEND}"
S="${WORKDIR}/${MY_PN}-releases-${PV}/${MY_PN}"
src_prepare() {
# Needed to make the --with-coin-instdir in src_configure happy.
dodir /usr
# They don't need to guess at this, but they do, and get it wrong...
sed -e "s:lib/pkgconfig:$(get_libdir)/pkgconfig:g" \
-i configure \
|| die "failed to fix the pkgconfig path in ${S}/configure"
default
}
src_configure() {
local myeconfargs=(
--enable-dependency-linking
--with-coin-instdir="${ED}"/usr
$(use_with doc dot)
)
econf "${myeconfargs[@]}"
}
src_compile() {
emake all $(usex doc doxydoc "")
}
src_test() {
# NOT redundant! The build system has a "make check" target that does
# nothing, so if you don't specify "test" here, you'll get a no-op.
emake test
}
src_install() {
use doc && HTML_DOC=("${BUILD_DIR}/doxydocs/html/")
emake DESTDIR="${D}" install
# Duplicate junk, and in the wrong location.
rm -r "${ED}/usr/share/coin/doc/${MY_PN}" || die
use examples && dodoc -r examples
}
|
GitWeb