blob: e0891825d06262a2b16c4fce6b7c15fd4276694e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# Needed to build tests for now
CMAKE_MAKEFILE_GENERATOR=emake
inherit cmake
DESCRIPTION="C++ template static library of common data structures and algorithms"
HOMEPAGE="https://lemon.cs.elte.hu/trac/lemon/"
SRC_URI="https://lemon.cs.elte.hu/pub/sources/${P}.tar.gz"
LICENSE="Boost-1.0"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="+coin doc glpk static-libs test"
RESTRICT="!test? ( test )"
REQUIRED_USE="|| ( coin glpk )"
RDEPEND="coin? (
sci-libs/coinor-cbc:=
sci-libs/coinor-clp:=
)
glpk? ( sci-mathematics/glpk:= )"
DEPEND="${RDEPEND}"
BDEPEND="doc? (
app-doc/doxygen
app-text/ghostscript-gpl
<dev-libs/mathjax-3
)"
PATCHES=(
"${FILESDIR}"/${P}-multilib.patch
"${FILESDIR}"/${PN}-1.3-as-needed.patch
)
src_prepare() {
local t
for t in \
max_clique \
max_flow \
graph_utils \
random \
time_measure \
tsp; do
sed -i -e "/${t}_test/d" test/CMakeLists.txt || die
done
sed -i \
-e '/ADD_TEST(lp_test lp_test)/d' \
-e '/ADD_DEPENDENCIES(check lp_test)/d' \
test/CMakeLists.txt || die
cmake_comment_add_subdirectory demo
use doc || cmake_comment_add_subdirectory doc
use test || cmake_comment_add_subdirectory test
cmake_src_prepare
}
src_configure() {
local mycmakeargs=(
-DLEMON_ENABLE_COIN=$(usex coin)
-DLEMON_ENABLE_GLPK=$(usex glpk)
)
use coin && mycmakeargs+=( -DCOIN_ROOT_DIR="${EPREFIX}/usr" )
if use doc; then
mycmakeargs+=(
-DLEMON_DOC_MATHJAX_RELPATH="${EPREFIX}/usr/share/mathjax"
-DLEMON_DOC_SOURCE_BROWSER=$(usex doc)
-DLEMON_DOC_USE_MATHJAX=$(usex doc)
)
fi
cmake_src_configure
}
src_test() {
cd "${S}" || die
emake -C "${BUILD_DIR}" check
}
src_install() {
cmake_src_install
# TODO: Upstream needs to see the light of GNUInstallDirs
if use doc; then
mv "${ED}"/usr/share/doc/lemon/html "${ED}"/usr/share/doc/${PF} || die
rmdir "${ED}"/usr/share/doc/lemon || die
fi
}
|
GitWeb