blob: 4a0b4a7b70ae0692513abc8a95c26ad22ab3e693 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
#inherit eutils multilib toolchain-funcs
inherit toolchain-funcs
DESCRIPTION="Utility to detect other OSs on a set of drives"
HOMEPAGE="http://packages.debian.org/source/sid/os-prober"
SRC_URI="mirror://debian/pool/main/${PN::1}/${PN}/${PN}_${PV}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
src_prepare() {
# use default GNU rules
rm Makefile || die 'rm Makefile failed'
# Fix references to grub-mount
sed -i -e 's:grub-mount:grub2-mount:g' \
common.sh \
linux-boot-probes/common/50mounted-tests \
os-probes/common/50mounted-tests
}
src_compile() {
tc-export CC
emake newns
}
src_install() {
dobin os-prober linux-boot-prober
# Note: as no shared libraries are installed, /usr/lib is correct
exeinto /usr/lib/os-prober
doexe newns
insinto /usr/share/os-prober
doins common.sh
keepdir /var/lib/os-prober
local debarch=${ARCH%-*} dir
case ${debarch} in
amd64) debarch=x86 ;;
ppc|ppc64) debarch=powerpc ;;
esac
for dir in os-probes{,/mounted,/init} linux-boot-probes{,/mounted}; do
exeinto /usr/lib/$dir
doexe $dir/common/*
if [[ -d $dir/$debarch ]]; then
doexe $dir/$debarch/*
fi
done
if use amd64 || use x86; then
exeinto /usr/lib/os-probes/mounted
doexe os-probes/mounted/powerpc/20macosx
fi
dodoc README TODO debian/changelog
}
pkg_postinst() {
elog "If you intend for os-prober to detect versions of Windows installed on"
elog "NTFS-formatted partitions, your system must be capable of reading the"
elog "NTFS filesystem. One way to do this is by installing sys-fs/ntfs3g"
}
|
GitWeb
