blob: 113b188e44b1decee9e4f0a55b8d7f7bb822f79d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1 systemd
DESCRIPTION="A simple CalDAV calendar server"
HOMEPAGE="https://radicale.org/"
SRC_URI="https://github.com/Kozea/Radicale/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
MY_P="Radicale-${PV}"
RDEPEND="
>=acct-user/radicale-0-r2
acct-group/radicale
dev-python/bcrypt[${PYTHON_USEDEP}]
dev-python/defusedxml[${PYTHON_USEDEP}]
dev-python/passlib[${PYTHON_USEDEP}]
dev-python/python-dateutil[${PYTHON_USEDEP}]
dev-python/vobject[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
sys-apps/util-linux
"
BDEPEND="
${RDEPEND}
test? (
dev-python/waitress[${PYTHON_USEDEP}]
)
"
distutils_enable_tests --install pytest
S="${WORKDIR}/${MY_P}"
RDIR=/var/lib/"${PN}"
DOCS=( DOCUMENTATION.md CHANGELOG.md )
src_prepare() {
sed -i '/^addopts =/d' setup.cfg || die
distutils-r1_src_prepare
}
python_test() {
epytest radicale/tests/
}
python_install_all() {
rm README* || die
# init file
newinitd "${FILESDIR}"/radicale-r3.init.d radicale
systemd_dounit "${FILESDIR}/${PN}.service"
# directories
keepdir "${RDIR}"
fperms 0750 "${RDIR}"
fowners "${PN}:${PN}" "${RDIR}"
# config file
insinto /etc/"${PN}"
doins config
# fcgi and wsgi files
exeinto /usr/share/"${PN}"
doexe radicale.wsgi
distutils-r1_python_install_all
}
pkg_postinst() {
local _erdir="${EROOT}${RDIR}"
einfo "A sample WSGI script has been put into ${EROOT}/usr/share/${PN}."
einfo "You will also find there an example FastCGI script."
if [[ $(stat --format="%U:%G:%a" "${_erdir}") != "${PN}:${PN}:750" ]]
then
ewarn ""
ewarn "Unsafe file permissions detected on ${_erdir}."
ewarn "This probably comes from an earlier version of this ebuild."
ewarn "To fix run:"
ewarn "# \`chown -R ${PN}:${PN} ${_erdir}\`"
ewarn "# \`chmod 0750 ${_erdir}\`"
ewarn "# \`chmod -R o= ${_erdir}\`"
fi
}
|
GitWeb