blob: 6bab6cc56eb3f3bf5c433eeb2d81dc90bf2ca60f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit desktop multilib savedconfig toolchain-funcs
DESCRIPTION="simple terminal implementation for X"
HOMEPAGE="https://st.suckless.org/"
SRC_URI="https://dl.suckless.org/st/${P}.tar.gz"
LICENSE="MIT-with-advertising"
SLOT="0"
KEYWORDS="amd64 ~arm arm64 ~hppa ppc64 ~riscv x86"
IUSE="savedconfig"
RDEPEND="
>=sys-libs/ncurses-6.0:0=
media-libs/fontconfig
x11-libs/libX11
x11-libs/libXft
"
DEPEND="
${RDEPEND}
virtual/pkgconfig
x11-base/xorg-proto
"
src_prepare() {
default
sed -i \
-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
-e '/^STLDFLAGS/s|= .*|= $(LDFLAGS) $(LIBS)|g' \
-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
config.mk || die
sed -i \
-e '/tic/d' \
Makefile || die
restore_config config.h
}
src_configure() {
sed -i \
-e "s|pkg-config|$(tc-getPKG_CONFIG)|g" \
config.mk || die
tc-export CC
}
src_install() {
emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
dodoc TODO
make_desktop_entry ${PN} simpleterm utilities-terminal 'System;TerminalEmulator;' ''
save_config config.h
}
pkg_postinst() {
if ! [[ "${REPLACING_VERSIONS}" ]]; then
elog "Please ensure a usable font is installed, like"
elog " media-fonts/corefonts"
elog " media-fonts/dejavu"
elog " media-fonts/urw-fonts"
fi
}
|
GitWeb
